Converting 1 to January etc.

ole_v2 · December 10th, 2007, 10:23 AM

I want to convert

Code:

        <postedAt>
            <year>2007</year>
            <month>12</month>
            <day>10</day>
        </postedAt>

to

Code:

December 2007

I'm currently using

Code:

    <xsl:template match="postedAt">
        <xsl:apply-templates select="month" mode="word"/>
        <xsl:text> </xsl:text>
        <xsl:apply-templates select="year"/>
    </xsl:template>

    <x:date>January</x:date>
    <x:date>February</x:date>
    <x:date>March</x:date>
    <x:date>April</x:date>
    <x:date>May</x:date>
    <x:date>June</x:date>
    <x:date>July</x:date>
    <x:date>August</x:date>
    <x:date>September</x:date>
    <x:date>October</x:date>
    <x:date>November</x:date>
    <x:date>December</x:date>

    <xsl:template match="month" mode="word">
        <xsl:value-of select="document('')//x:date[position() = .]" />
    </xsl:template>

the last template in that code doesn't appear to be working. What I don't understand is that this works:

Code:

document('')//x:date[position() = 12]

with the 12 instead of .
and yet . contains 12 (I verified this with value-of). I tried using number() but that made no difference.

samjudson · December 10th, 2007, 10:38 AM

The problem is that "." in inside the square brackets [] is the current context. This changes inside a predicate.

It might be better to use call template

<xsl:template name="word-to-month">
  <xsl:param name="num" as="xs:integer"/>
  <xsl:value-of select="document('')//x:date[position() = $num]" />
</xsl:template>

And then:

<xsl:call-template name="word-to-month">
  <xsl:with-param name="num" select="xs:integer(month)"/>
</xsl:call-template>

If you're not using XSLT 2.0 then skip the as="xs:integer" bit obviously.

/- Sam Judson : Wrox Technical Editor -/

ole_v2 · December 10th, 2007, 11:02 AM

Thanks samjudson. I forgot about the predicate context change behaviour.

mhkay · December 10th, 2007, 11:07 AM

The context (.) inside a predicate is different from the context outside the predicate. Inside the predicate it refers to the node currently being tested. Use current() instead.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference