avoiding duplications

josephx · January 4th, 2008, 09:37 PM

How do I display the name() nodes of author, title, place, and extra just once using XPath expression?

I tried using something like <xsl:value-of select="/*/*/*name()"/> but then it outputs all the author,title, place and extra element nodes found in an xml document.

sample xml document

Code:

<?xml version="1.0"?>
<?xml-stylesheet href="test.xsl" type="text/xsl"?>
<rss>
   <channel>
    <item>
        <author>John</author>
        <title>Earthquake</title>
        <place>Japan</place>
    </item>
    <item>
        <author>Mike</author>
        <title>Microsoft Visual Sutdio 2008 now available</title>
                <extra>....</extra>
        <place>United States</place>
    </item>
    <item>
        <author>Jean</author>
        <title>Flood</title>
        <place>England</place>
    </item>
    <item>
        <author>Matt</author>
        <title>Silent Night</title>
        <place>California</place>
    </item>
    <item>
        <author>James</author>
        <title>Fire</title>
        <place>Rome</place>
        </item>
   </channel>
</rss>

mhkay · January 5th, 2008, 06:06 AM

In XPath 2.0: distinct-values(//*/name())

In XPath 1.0 - it can't be done. You want to return a set of strings, and there's no such data type in XPath 1.0.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

josephx · January 5th, 2008, 07:43 AM

Thanks for replying Michael.

Do we need to use "Saxon XSLT application" in order to be able to use XPath 2.0? In fact.. I think XPath 2.0 doesn't seem to be supported in most applications yet, because it was published last Jan 2007 - please correct me if I'm wrong.

Quote:

quote:Originally posted by mhkay
In XPath 2.0: distinct-values(//*/name())

In XPath 1.0 - it can't be done. You want to return a set of strings, and there's no such data type in XPath 1.0.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

mhkay · January 5th, 2008, 08:21 AM

You're right, most free-standing XPath implementations still support only XPath 1.0. However, support for 2.0 is becoming more common, for example it's available in Stylus Studio, Oxygen, and XML Spy. If you're using a product that doesn't support it yet, consider switching, or asking your vendor to get a move on.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Martin Honnen · January 5th, 2008, 09:41 AM

There is not a single XPath 1.0 expression that gives you the unique names but an XSLT 1.0 stylesheet can nevertheless extract them using a grouping approach, here is a stylesheet that does that:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:output method="text"/>

  <xsl:key name="by-name" match="*/*/*/*" use="name()"/>

  <xsl:template match="/">
    <xsl:for-each select="*/*/*/*[generate-id() = generate-id(key('by-name', name())[1])]">
      <xsl:value-of select="name()"/>
      <xsl:if test="position() != last()">
        <xsl:value-of select="', '"/>
      </xsl:if>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

josephx · January 5th, 2008, 04:29 PM

Thank you Martin. - I completely forgot about the capabilities of XSL.