I'm a little new to xsl and I am try to sort some unrelated strings.

I'm using a lookup table to and populating with some static data and some variables.

This is an example of what I have tried:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:map="http://test.com/xslt/maps">
    <xsl:template match="/">
                <xsl:variable name="johnBic1">mfil</xsl:variable>
              <xsl:variable name="johnBic2">gsil</xsl:variable>
                <map:bics>
            <map:bic abbrev="bic3">janurary</map:bic>
            <map:bic abbrev="bic4">Februrary</map:bic>
                        <map:bic abbrev="bic5"><xsl:value-of select="$johnBic1"></xsl:value-of></map:bic>
            <map:bic abbrev="bic6"><xsl:value-of select="$johnBic2"></xsl:value-of></map:bic>
            </map:bics>


        <xsl:for-each select="document('client.deal.swift.320.TestMonthM ap')/*/map:bics/map:bic">
            <xsl:sort select="." data-type="text" order="ascending"/>
            <xsl:value-of select="."></xsl:value-of>
        </xsl:for-each>

    </xsl:template>
</xsl:stylesheet>

This does not sor=t the values correctly.

When I declare the map outside the template I can get it to sort correctly. However, it ignores the variables I have declared. Why does this happen?

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:map="http://test.com/xslt/maps">
  <xsl:variable name="johnBic1">mfil</xsl:variable>
              <xsl:variable name="johnBic2">gsil</xsl:variable>
                <map:bics>
            <map:bic abbrev="bic3">janurary</map:bic>
            <map:bic abbrev="bic4">Februrary</map:bic>
                        <map:bic abbrev="bic5"><xsl:value-of select="$johnBic1"></xsl:value-of></map:bic>
            <map:bic abbrev="bic6"><xsl:value-of select="$johnBic2"></xsl:value-of></map:bic>
            </map:bics>

    <xsl:template match="/">


        <xsl:for-each select="document('')/*/map:bics/map:bic">
            <xsl:sort select="." data-type="text" order="ascending"/>
            <xsl:value-of select="."></xsl:value-of>
        </xsl:for-each>

    </xsl:template>
</xsl:stylesheet>

Thanks for your help in advance.

<map:bics>
...
</map:bics>

<xsl:for-each select="document('client.deal.swift.320.TestMonthM ap')/*/map:bics/map:bic">

I've no idea what's in that document you are reading, but it certainly isn't the map:bics element you have just created. The output of your stylesheet isn't available to be read until the stylesheet is finished (and if you try and read it before then, anything could happen.)

In your second example, <map:bics> is a "user data element". This is completely passive content, there is no attempt to look inside it to see if it contains any instructions. I would expect that when you read it, it's exactly as if you read an external data file - if it contains XSLT instructions, you will simply read those instructions, you won't execute them.

So, take a step back, and try and explain what problem you are trying to solve. Then we can help suggest the right way to go about it.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Ok,

Sorry for the brief explanation. Its been a long day...

Idealy I want to sort some variables that will be passed in to the stylesheet. We are using formula's to generate these values.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:map="http://test.com/xslt/maps">

    <xsl:param name="ourBic"/>
        <xsl:param name="cntBic"/>

        <map:bics>
            <map:bic abbrev="bic1"><xsl:value-of select="$ourBic"></xsl:value-of></map:bic>
            <map:bic abbrev="bic2"><xsl:value-of select="$cntBic"></xsl:value-of></map:bic>
        </map:bics>

<xsl:template match="/">
        <xsl:for-each select="document('client.deal.swift.320.TestMonthM apOrig')/*/map:bics/map:bic">
            <xsl:sort select="." order="ascending"/>
            <xsl:value-of select="."></xsl:value-of>
        </xsl:for-each>
    </xsl:template>

The idea being that we can pass in two strings to this stylesheet and it will return them in order. client.deal.swift.320.TestMonthMapOrig is referring to itself.
On docs I have read it suggested using document('')/*/map:bics/map:bic as this refers to the current stylesheet.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:map="http://test.com/xslt/maps">

    <map:bics>
            <map:bic abbrev="bic3">MFIL</map:bic>
            <map:bic abbrev="bic4">GSIL</map:bic>
        </map:bics>

    <xsl:template match="/">

        <xsl:for-each select="document('client.deal.swift.320.TestMonthM ap')/*/map:bics/map:bic">
            <xsl:sort select="." data-type="text" order="ascending"/>
            <xsl:value-of select="."></xsl:value-of>
        </xsl:for-each>

    </xsl:template>
</xsl:stylesheet>

The stylesheet above returns "GSILMFIL" I want to be able to do this with dynamic variables not static values.


Thank you

The limitations of XSLT 1.0 are really frustrating - the only thing you can sort is a node-set; there is no way of creating a node-set and sorting it in a single transformation without the xx:node-set() extension; and there is no way of comparing two strings except by sorting them.

Is there any reason you have to use XSLT 1.0?

In 2.0 it becomes really easy:

<xsl:for-each select="$ourBic, $cntBic">
  <xsl:sort select="."/>
  ...
</xsl:for-each>

Or if you prefer:

<xsl:for-each select="min(($ourBic, $cntBic)), max(($ourBic, $cntBic))">
  ...
</xsl:for-each>

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

The app I am using only supports 1.0. I will look further into xx:node-set().

Thanks for your help this far.

Sorry, how do you do this with the saxon extensions?

> Sorry, how do you do this with the saxon extensions?

Do you mean with Saxon 6.5.x, which implements XSLT 1.0? (I'm not sure why anyone would be using that in preference to Saxon 9.0, unless you've got some strange constraint like being tied to Java 1.1!)

Like most XSLT 1.0 processors Saxon 6.5.x has a saxon:node-set() extension, which allows you to do

<xsl:variable name="temp">
  <a><xsl:value-of select="$var1"/></a>
  <a><xsl:value-of select="$var2"/></a>
</xsl:variable>

<xsl:for-each select="saxon:node-set($temp)/a">
  <xsl:sort select="."/>
  ....

Or in fact you don't need the saxon:node-set($temp), you can just write select="$temp", provided you say version="1.1" on the xsl:stylesheet element.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Thanks Michael. This is working for me in Oxygen but not in the application I am using. Think its time to contact them.

Thanks again