Comparing with blank value using xsl:if

vidhiS · March 11th, 2008, 01:49 AM

Hi

My xml is as follows
<?xml version="1.0" encoding="UTF-8"?>
<Rels>
<Rel>
<RelName>Report Causes</RelName>
<CPName>Common Core </CPName>
<DestName>Dst</DestName>
<UserID>JPM9216</UserID>
<AttrName>Position</AttrName>
<AttrValue>ALL</AttrValue>
<Version>P</Version>
</Rel>
<Rel>
<RelName>Causes Mainte</RelName>
<CPName>link update</CPName>
<DestName>ge_Number</DestName>
<UserID>AC2793</UserID>
<AttrName></AttrName>
<AttrValue></AttrValue>
<Version></Version>
</Rel>
</Rels>

My XSLT is as follows

<?xml version='1.0' encoding='utf-8' ?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="html"/>

<xsl:key name="Rels" match="Rel" use="RelName"/>

<xsl:template match="/">
    <xsl:apply-templates/>
</xsl:template>

<xsl:template match="Rels">
    <h3 > History</h3>

    <xsl:for-each select="//Rel[generate-id(.)=generate-id(key('Rels',RelName))]">

           <center ><h4><xsl:value-of select="RelName"/> </h4></center>

          <table border="1" width='100%' >
              <tr>
                <th bgcolor='#0033CC'><b>Name</b></th>
                <th bgcolor='#0033CC'><b>Destination Name</b></th>
                <th bgcolor='#0033CC'><b>User Name</b></th>
                <th bgcolor='#0033CC'><b>Attributes</b></th>
                  <th bgcolor='#0033CC'><b>Version</b></th>
        </tr>

             <xsl:for-each select="key('Rels',RelName)">
             <tr bgcolor='BIEGE'>
                    <td width="20%" ><xsl:value-of select="CPName"/></td>
                    <td width="20%" ><xsl:value-of select="DestName"/></td>
                    <td width="20%" ><xsl:value-of select="UserID"/></td>
                    <xsl:variable name="test" ><xsl:value-of select="AttrName"/> </xsl:variable>
                    <xsl:if test="$test = ' ' ">
                        <td width="20%" >No Value</td>
                    </xsl:if>
                    <xsl:if test="$test != ' ' "><td width="20%" ><xsl:value-of select="$test"/></td> </xsl:if>
                    <td width="20%" ><xsl:value-of select="Version"/></td>
            </tr>
            </xsl:for-each> </table>
        <br/><br/>
    </xsl:for-each>
</xsl:template>
</xsl:stylesheet>

if the value in node AttrName is blank i want to display"No value" string in table else it should display the value in that node, but my xsl:if part is not working. for all it shows only blank rows :(
Plz help.

joefawcett · March 11th, 2008, 04:00 AM

I would do something like:

Code:

<xsl:variable name="attrName" >
              <xsl:choose>
                <xsl:when test="normalize-space(AttrName) != ''">
                  <xsl:value-of select="AttrName"/>
                </xsl:when>
                <xsl:otherwise>
                  <xsl:text>No Value</xsl:text>
                </xsl:otherwise>
              </xsl:choose>
            </xsl:variable>
            <td width="20%" >
              
                <xsl:value-of select="$attrName"/>
              
            </td>

Your effort to group also looks a bit suspect, I think you need to change this:

Code:

<xsl:for-each select="Rel[generate-id(.)=generate-id(key('Rels',RelName))]">

to this:

Code:

<xsl:for-each select="Rel[generate-id(.)=generate-id(key('Rels',RelName)[1])]">

The full XSLT:

Code:

<?xml version='1.0' encoding='utf-8' ?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"  version="1.0">
  <xsl:output method="html"/>

  <xsl:key name="Rels" match="Rel" use="RelName"/>

  <xsl:template match="/">
    <xsl:apply-templates/>
  </xsl:template>

  <xsl:template match="Rels">
    <h3 > History</h3>

    <xsl:for-each select="Rel[generate-id(.)=generate-id(key('Rels',RelName)[1])]">

      <center >
        <h4>
          <xsl:value-of select="RelName"/>
        </h4>
      </center>

      <table border="1" width='100%' >
        <tr>
          <th bgcolor='#0033CC'>

              <b>Name</b>

          </th>
          <th bgcolor='#0033CC'>

              <b>Destination Name</b>

          </th>
          <th bgcolor='#0033CC'>

              <b>User Name</b>

          </th>
          <th bgcolor='#0033CC'>

              <b>Attributes</b>

          </th>
          <th bgcolor='#0033CC'>

              <b>Version</b>

          </th>
        </tr>

        <xsl:for-each select="key('Rels',RelName)">
          <tr bgcolor='BIEGE'>
            <td width="20%" >

                <xsl:value-of select="CPName"/>

            </td>
            <td width="20%" >

                <xsl:value-of select="DestName"/>

            </td>
            <td width="20%" >

                <xsl:value-of select="UserID"/>

            </td>
            <xsl:variable name="attrName" >
              <xsl:choose>
                <xsl:when test="normalize-space(AttrName) != ''">
                  <xsl:value-of select="AttrName"/>
                </xsl:when>
                <xsl:otherwise>
                  <xsl:text>No Value</xsl:text>
                </xsl:otherwise>
              </xsl:choose>
            </xsl:variable>
            <td width="20%" >

                <xsl:value-of select="$attrName"/>

            </td>
            <td width="20%" >

                <xsl:value-of select="Version"/>

            </td>
          </tr>
        </xsl:for-each>
      </table>
      <br/>
      <br/>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

As it happens both work as you only have two distinct entries in your XML. Perhaps look at the examples here: http://www.jenitennison.com/xslt/gro...muenchian.html

--

Joe (Microsoft MVP - XML)

mhkay · March 11th, 2008, 04:01 AM

Let's look at the variable declaration:

<xsl:variable name="test" >
<xsl:value-of select="AttrName"/>
</xsl:variable>

This is a very convoluted way of writing:

<xsl:variable name="test" select="AttrName" />

What you want is a string, but instead of defining the variable as a string you are evaluating the string, putting the result into a text node, attaching that text node to a document node, and then computing the string value of the document node every time you reference the variable. If you don't care about performance and if you are bonused on the number of lines of code you write, this is fine, but otherwise it's horrible. Can't blame you though, it's an incredibly common blunder: yours is the second post this morning on this forum to do it.

Now your test. In your sample data you have <AttrName></AttrName>. The string value of that element is a zero-length string. But your test is

<xsl:if test="$test = ' ' ">

which tests for a string containing a single space. You need

<xsl:if test="$test = '' ">

Or if you want to test for all strings containing no characters other than whitespace, use

<xsl:if test="not(normalize-space($test))">

Of course you could also do this in the variable:

<xsl:variable name="test" select="normalize-space(AttrName)" />

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

vidhiS · March 11th, 2008, 07:16 AM

Thanks a lot for your valuable suggestions.
That is really helping in my work.