XSLT conversion question

jastao · April 29th, 2008, 02:42 PM

Here is the XML I have, anyone kw how i can use xslt to convert from

<city name="LA">
  <place>1</place>
</city>
<city name="LA">
  <place>2</place>
</city>
<city name="Boston">
  <place>1</place>
</city>

to

<city name="LA">
  <place>1</place>
  <place>2</place>
</city>
<city name="Boston">
  <place>1</place>
</city>

Thanks

mphare · April 29th, 2008, 04:09 PM

Hi,

I put <wrapper></wrapper> elements around your elements so I would have a single root element.

But here's the xslt:

Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">

    <xsl:template match="/">

        <wrapper>
            <xsl:text>#x0A;</xsl:text>
            <xsl:for-each-group select="//city" group-by="@name">
                <xsl:text>#x0A;</xsl:text>
                <xsl:element name="city">
                    <xsl:attribute name="name">
                        <xsl:value-of select="current-grouping-key()"/>
                    </xsl:attribute>

                    <xsl:for-each select="current-group()">
                        <xsl:text>#x0A;</xsl:text>
                        <xsl:element name="place">
                            <xsl:value-of select="./place"/>
                        </xsl:element>
                    </xsl:for-each>
                    <xsl:text>#x0A;</xsl:text>
                </xsl:element>
            </xsl:for-each-group>
            <xsl:text>#x0A;</xsl:text>
        </wrapper>
    </xsl:template>
</xsl:stylesheet>

It can be made more efficient, maybe not explicitly nameing the element and attribute names, but pulling them from the source nodes.

But I did this is just a few minutes.. so..

Hope this helps

- m

------------------------
GnuPG Key fingerprint = 1AD4 726D E359 A31D 05BF ACE5 CA93 7AD5 D8E3 A876

Michael Hare

mhkay · April 29th, 2008, 09:00 PM

This is a standard grouping problem, in fact it arrived just as I was about to start a session on grouping in the XSLT class I am teaching this week, so I used the example as a classroom exercise just to prove I can think on my feet.

Here's the XSLT 2.0 solution:

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output indent="yes"/>

<xsl:template match="/">
<cities>
  <xsl:for-each-group select="cities/city"
      group-by="@name">
      <city name="{current-grouping-key()}">
        <xsl:copy-of select="current-group()/place"/>
      </city>
  </xsl:for-each-group>
</cities>
</xsl:template>

</xsl:stylesheet>

For information on grouping in XSLT 1.0, see http://www.jenitennison.com/xslt/grouping

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

mhkay · April 29th, 2008, 09:09 PM

All this xsl:element and xsl:attribute stuff will work, but XSLT is already verbose enough without making it worse. Why not write this as

        <wrapper>
            <xsl:text>#x0A;</xsl:text>
            <xsl:for-each-group select="//city" group-by="@name">
                <xsl:text>#x0A;</xsl:text>
                <city name="{current-grouping-key()}">
                    <xsl:for-each select="current-group()">
                        <xsl:text>#x0A;</xsl:text>
                        <xsl:copy-of select="place"/>
                    </xsl:for-each>
                    <xsl:text>#x0A;</xsl:text>
                </city>
            </xsl:for-each-group>
            <xsl:text>#x0A;</xsl:text>
        </wrapper>

And you can probably simplify further by getting rid of the explicit newlines and relying on xsl:output indent="yes" instead.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference