XML element with delimited values and XSLT

Martin Honnen · May 7th, 2008, 06:27 AM

I posted a complete working stylesheet. Does that not work for you?
As for the snippet you have provided, I don't see how that could "screw up" or "bomb out" the result but those terms do not tell us anyway what exactly happens.
Please provide a minimal and complete stylesheet and show us the result you get and explain in what way exactly it is screwed up.
If the stylesheet transformation does not run at all ("bomb out") then show us the .NET code you use to run the transformtion.

--
Martin Honnen
Microsoft MVP - XML

Clark Kent · May 7th, 2008, 09:12 AM

Sorry guys, I didnt even bother to check whether my code was failing and that is the case. Here is my .Net code:

XPathDocument myXPathDocument = new XPathDocument("C:\\xmlSource.xml");
                XslTransform myXslTransform = new XslTransform();
                XmlTextWriter writer = new XmlTextWriter("C:\\transformed.xml", null);
                myXslTransform.Load("C:\\NewTransform.xslt");
                myXslTransform.Transform(myXPathDocument, null, writer);
                writer.Close();
                StreamReader stream = new StreamReader("C:\\transformed.xml");
                Console.Write(stream.ReadToEnd());

I'm getting the following error during myXslTransform.Transform().

"Cannot find the script or external object that implements prefix 'exsl'."

Here is the top of my stylesheet(I downloaded the str.xsl and corresponding files so the import is OK):

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:str="http://exslt.org/strings"
                xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="str exsl">

  <xsl:import href="str.xsl" />

Here is the chunk of the transform I'm trying to parse through the "Market" element in the original example I posted above:

<xsl:variable name="tokens">
         <xsl:call-template name="str:_tokenize-delimiters">
          <xsl:with-param name="string" select="Market"></xsl:with-param>
          <xsl:with-param name="delimiters" select="'|'"></xsl:with-param>
        </xsl:call-template>
      </xsl:variable>

        <xsl:for-each select="exsl:node-set($tokens)/token">
          <Market>
            <xsl:value-of select="."/>
          </Market>
        </xsl:for-each>

Also, I've got all three of the str templates referenced at the bottom of my stylesheet.

Does this help? I really appreciate the help from you guys!

Martin Honnen · May 7th, 2008, 09:52 AM

Are you still using .NET 1.x? Otherwise you should not use the obsolete XslTransform but rather XslCompiledTransform instead. With that my stylesheet works.
If you want to continue to use XslTransform then you can't use exsl:node-set as it does not support that. Instead you need to use a different namespace:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:str="http://exslt.org/strings"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt"
  version="1.0"
  exclude-result-prefixes="str msxsl">

  <xsl:include href="http://www.exslt.org/str/functions/tokenize/str.tokenize.template.xsl"/>

  <xsl:output method="xml" indent="yes"/>

  <xsl:strip-space elements="*"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="market">
    <xsl:copy>
      <xsl:variable name="tokens">
        <xsl:call-template name="str:tokenize">
          <xsl:with-param name="string" select="."/>
          <xsl:with-param name="delimiters" select="'|'"/>
        </xsl:call-template>
      </xsl:variable>
      <xsl:for-each select="msxsl:node-set($tokens)/token">
        <m>
          <xsl:value-of select="."/>
        </m>
      </xsl:for-each>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

--
Martin Honnen
Microsoft MVP - XML

Clark Kent · May 7th, 2008, 09:54 AM

It appears the problem is definitely with the for-each loop. If I just us the tokens variable and spit that to the resulting XML, I get the original input with the delimiters removed.

Clark Kent · May 7th, 2008, 09:55 AM

OK, I'll give the CompiledTransform a shot.

Clark Kent · May 7th, 2008, 10:10 AM

SWEET! It's working! Just had to change a few things around in the .Net code. Thank you both for the help so much - sorry for being a pain in the butt.
:)