Nested Bullet List

tims · May 8th, 2008, 12:07 AM

I need to transform[list]
        <li>ddff</li>
        <li>ffffff</li>
        [list]
          <li>fffrrtytty</li>
          <li>tytyty</li>
        </ul>
      </ul>

to [list]
        <li>ddff</li>
        <li>ffffff
        [list]
          <li>fffrrtytty</li>
          <li>tytyty</li>
        </ul></li>
      </ul>

i.e if Nested ul is present it should come under upper node <li>

Martin Honnen · May 8th, 2008, 06:37 AM

Here is an XSLT 1.0 stylesheet that performs the transformation:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="ul">
    <xsl:copy>
      <xsl:apply-templates select="li[1]"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="li">
    <xsl:copy>
      <xsl:apply-templates/>
      <xsl:apply-templates select="following-sibling::*[1][self::ul]"/>
    </xsl:copy>
    <xsl:apply-templates select="following-sibling::li[1]"/>
  </xsl:template>

</xsl:stylesheet>

--
Martin Honnen
Microsoft MVP - XML