Global parameter calculation inside template

Volder · June 20th, 2008, 05:27 AM

Hello.
Is the following possible:
- define global parameter;
- assign a value to it inside a template;
- use this value of a parameter in the global level context.

smth like:

Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:param name="var"/>
    <xsl:template match="/">
        <root>
            <node1>1</node1>
            <xsl:call-template name="aaa"/>
            <node3>
                <xsl:value-of select="$var"/>
            </node3>
        </root>
    </xsl:template>
    <xsl:template name="aaa">
        <xsl:with-param name="var" select="3"/>
        <node2>2</node2>
    </xsl:template>
</xsl:stylesheet>

to get the following result:

Code:

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <node1>1</node1>
    <node2>2</node2>
    <node3>3</node3>
</root>

mhkay · June 20th, 2008, 05:33 AM

No, XSLT is a declarative functional language not a procedural one.

Describe your problem, rather than your procedural approach to solving it, and we might be able to help you.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Volder · June 20th, 2008, 06:49 AM

Quote:

quote:Describe your problem, rather than your procedural approach to solving it, and we might be able to help you.

ok, if to simplify it a lot I have an XML:

Code:

<?xml version="1.0" encoding="windows-1251"?>
<?xml-stylesheet type="text/xsl" href="test_xsl.xsl" indent="yes" encoding="Windows-1251"?>
<root>
    <status>
        <name>START</name>
        <date>1</date>
    </status>
    <status>
        <name>END</name>
        <date>3</date>
    </status>
    <status>
        <name>START</name>
        <date>5</date>
    </status>
</root>

I need to get a new XML with information about latest START date and latest END date. But I need latest END date only in case it is later than latest START date.

So in my case the result would be:

Code:

  <?xml version="1.0" encoding="UTF-8" ?> 
- <root>
  <latest_START>5</latest_START> 
  <latest_END/>
  </root>

END date is empty, because we don't have it after latest START date.

I used XSL to find both latest dates:

Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="root">
        <root>
            <latest_START>
                <xsl:apply-templates select="status[name='START']">
                    <xsl:sort select="date" order="descending"/>
                </xsl:apply-templates>
            </latest_START>
            <latest_END>
                <xsl:apply-templates select="status[name='END']">
                    <xsl:sort select="date" order="descending"/>
                </xsl:apply-templates>
            </latest_END>
        </root>
    </xsl:template>
    <xsl:template match="status">
        <xsl:if test="position()=1">
            <xsl:value-of select="date"/>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

but in this case the latest END is incorrect.
I wanted to capture latest START date into variable and use it in:

Code:

<xsl:apply-templates select="status[name='END' and date>$last_START_date]">

Martin Honnen · June 20th, 2008, 07:04 AM

If you are using XSLT 2.0 then you can make use of the max function e.g.

Code:

<xsl:variable name="maxStart"
              select="max(/root/status[name = 'START']/date)"/>
<xsl:variable name="maxEnd"
              select="max(/root/status[name = 'END']/date)"/>

then you can simply compare

Code:

$maxStart > $maxEnd

--
Martin Honnen
Microsoft MVP - XML

Volder · June 20th, 2008, 07:16 AM

Quote:

quote:Originally posted by Martin Honnen
If you are using XSLT 2.0 then you can make use of the max function e.g.

sorry, forgot to mention - version 1.0
but still I can implement your solution through <xsl:for-each>+<xsl:sort>+position()=1

but still is there a simpler solution, than using 2 variables?
And I didn't want to use <xsl:for-each> and wanted to use it through <xsl:apply-templates>.

samjudson · June 20th, 2008, 07:27 AM

You can write a template to perform the 'max' functionality, much like EXSLT has here:

http://www.exslt.org/math/functions/...x.template.xsl

<xsl:variable name="maxStart">
<xsl:call-template name="math:max">
<xsl:with-param name="nodes" select="/root/status[name = 'START']/date"/>
</xsl:call-template>
</xsl:variable>

/- Sam Judson : Wrox Technical Editor -/

Martin Honnen · June 20th, 2008, 07:35 AM

Here is an adaption of the stylesheet you posted:

Code:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:template match="root">
        <root>
            <xsl:variable name="latest_start">
                <xsl:apply-templates select="status[name='START']">
                    <xsl:sort select="date" order="descending"/>
                </xsl:apply-templates>
            </xsl:variable>
            <latest_START>
              <xsl:value-of select="$latest_start"/>
            </latest_START>
            <latest_END>
                <xsl:apply-templates select="status[name='END' and date &gt; $latest_start]">
                    <xsl:sort select="date" order="descending"/>
                </xsl:apply-templates>
            </latest_END>
        </root>
    </xsl:template>
    <xsl:template match="status">
        <xsl:if test="position()=1">
            <xsl:value-of select="date"/>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

Applied to the sample input you posted earlier it outputs

Code:

<root>
   <latest_START>5</latest_START>
   <latest_END/>
</root>

--
Martin Honnen
Microsoft MVP - XML

Volder · June 20th, 2008, 07:50 AM

Quote:

quote:
Here is an adaption of the stylesheet you posted:

thanks - I was so near :)
it is always useful to have a fresh look at it.

mhkay · June 20th, 2008, 08:10 AM

If the status events are always in order, then you don't need to use max() or sorting. You can just select the last one by position. The last START (assuming <root> as context item) is select="status[name='START'][last()]"; similarly the last END; you can test whether the last start has a following END using <xsl:if test="status[name='START'][last()]/following-sibling::status[name='END']"/>.

Certainly, this a problem that doesn't need procedural logic at all; the output can be described fairly easily as a function of the input.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference