Hi.

I have the following snippet of XML:
<Names>
  <Name correct="true">John Doe</Name>
  <Name correct="false">Joe Smith</Name>
  <Name correct="true">Jane Doe</Name>
  <Name correct="false">Billy Smith</Name>
</Names>


I like the output after XSL transformation to be the following:
NAMES: John Doe, Jane Doe.


Here is my snippet of XSLT so far:
<xsl:template match=Names">NAMES: <xsl:text/>
  <xsl:call-template name="Name_Template"/>
  <xsl:text>.</xsl:text>
</xsl:template>

<xsl:template name="Name_Template">
  <xsl:for-each select="Name">
     <xsl:if test="@correct='true'">
        <xsl:value-of select="."/>
        <xsl:if test="position()!=last()">
           <xsl:text>, </xsl:text>
        </xsl:if>
     </xsl:if>
  </xsl:for-each>
</xsl:template>


My output so far is the following, which is incorrect:
NAMES: John Doe, Jane Doe,.

The output has a comma beside the period, which I don't want it to be.

How do I modify XSLT to fix this? Any suggestions appreciated.

Jane Doe is the third child of <names> ,not the last.

It is the last comma I want to get rid of.

I want the output to be:
NAMES: John Doe, Jane Doe.

I don't want the output to be, which is currently doing:
NAMES: John Doe, Jane Doe,.

Remember that the XSLT checks the "correct" attribute before outputting a name.

I would suggest:

<xsl:template match="Names">
  <xsl:text>NAMES: </xsl:text>
  <xsl:apply-templates select="Name[@correct='true']"/>
  <xsl:text>.</xsl:text>
</xsl:template>

<xsl:template match="Name">
  <xsl:value-of select="."/>
  <xsl:if test="position()!=last()">, </xsl:if>
</xsl:template>

Michael Kay
http://www.saxonica.com/
Author, XSLT 2.0 and XPath 2.0 Programmer's Reference

maybe it is a method to help you,but i am not sure.
<xsl:template name="Name_Template">
  <xsl:for-each select="Name">
     <xsl:if test="@correct='true'">
        <xsl:value-of select="."/>
        <xsl:choose>
        <xsl:when test="position()!=last() and following-sibling::Name[@correct='true']">

           <xsl:text>, </xsl:text>
         </xsl:when>
        <xsl:otherwise></xsl:otherwise>
         <xsl:choose>
        </xsl:if>
     </xsl:if>
  </xsl:for-each>
</xsl:template>