Basic Positioning

zach_1988 · December 1st, 2008, 06:59 PM

Hi, this should be a fairly easy question as I'm new to the language:

I'm using an xSLT spreadsheet to convert an XML document into xHTML. Imagine the following xml:

<root>
<briefing>
This is all text but <bottom> this </bottom> should appear at the bottom of the page.
</briefing>
</root>

Obviously I can pick out that tag and edit the text within it:

<xsl:template match="bottom">

But how could I actually move it so it was at the bottom of the page separate from everything else?

Thanks for your help :)

mhkay · December 1st, 2008, 07:05 PM

You need to structure your code to match the structure of the output, not the structure of the input. So it's not a case of "when I find <bottom/> in the input, what should I do with it?" Rather it's a case of "at the end of processing a page, find the <bottom/> elements that need to be output here".

I don't know what output vocabulary you are using (HTML doesn't have pages - is it XSL-FO?) so I can't be more precise than that. Layout of footnotes can be a tricky subject and I'm no expert.

Michael Kay
http://www.saxonica.com/
Author, XSLT 2.0 and XPath 2.0 Programmer's Reference

zach_1988 · December 1st, 2008, 07:19 PM

Thanks for the reply,

In my case the xml document is simply linked to an xSLT stylesheet:

<?xml version="1.0"?>
<?xml-stylesheet type="text/xsl" href="bottom.xls"?>

Hmmm, so I need to display those nodes at the end of my body?

<?xml version='1.0'?>
<xsl:stylesheet version="1.0" xmlns:xsl="url" >

<xsl:template match="/" >
<html>
     <body>
         <xsl:apply-templates/>
     </body>
</html>
</xsl:template>

But if I was to call apply-templates again, I don't see how I could have it so it just displayed the <bottom> tag contents?

mhkay · December 1st, 2008, 07:30 PM

Well, one way would be:

<xsl:template match="/" >
   <html>
      <body>
         <xsl:apply-templates/>

         <h2>Notes</h2>
         <xsl:apply-templates select="//bottom" mode="footnote"/>
      </body>
   </html>
</xsl:template>

<xsl:template match="bottom">
  [<a href="#{generate-id()}"><xsl:number level="any"/></a>]
</xsl:template>

<xsl:template match="bottom" mode="footnote">
  <p><a name="{generate-id()}">
    [<xsl:number level="any"/>]
    <xsl:value-of select="."/></a></p>
</xsl:template>

When the bottom element is processed on the first pass, it generates a link. When it is processed again on the second pass, it generates the text of the footnote, together with an anchor for the link.

Michael Kay
http://www.saxonica.com/
Author, XSLT 2.0 and XPath 2.0 Programmer's Reference

zach_1988 · December 1st, 2008, 07:45 PM

Great, thankyou!