Stuck on XSLT problem

Martin Honnen · January 31st, 2009, 12:56 PM

First of all, the xsl:key element does not belong into an xsl:template element. Instead it should be a top level element i.e. a child of the xsl:stylesheet element.

As for your key definition <xsl:key name="by-name" match="Request/*" use="SomeTypeB"/>, what is that supposed to achieve? It matches child elements of 'Request' elements and defines the key value with use="SomeTypeB". In your XML sample that you posted earlier the children of the 'Request' element do not have any child named 'SomeTypeB' so that key does not make any sense to me. You would need to have e.g.

Code:

<Request>
  <Foo>
    <SomeTypeB>whatever</SomeTypeB>
  </Foo>
</Request>

for that key to make any sense as then for the 'Foo' child element of the 'Request' element the string value of the 'SomeType' child element would be the key value.

jiggs · January 31st, 2009, 01:05 PM

Quote:

Originally Posted by Martin Honnen

First of all, the xsl:key element does not belong into an xsl:template element. Instead it should be a top level element i.e. a child of the xsl:stylesheet element.

As for your key definition <xsl:key name="by-name" match="Request/*" use="SomeTypeB"/>, what is that supposed to achieve? It matches child elements of 'Request' elements and defines the key value with use="SomeTypeB". In your XML sample that you posted earlier the children of the 'Request' element do not have any child named 'SomeTypeB' so that key does not make any sense to me. You would need to have e.g.

Code:

<Request>
  <Foo>
    <SomeTypeB>whatever</SomeTypeB>
  </Foo>
</Request>

for that key to make any sense as then for the 'Foo' child element of the 'Request' element the string value of the 'SomeType' child element would be the key value.

I recognize now that it's wrong since especially you mentioened that the generate-id part is central to Meunchin grouping which I never had. I was also confused with the last part of the key statement .. i.e. the SomeTypeB .. in theory what I wanted to do was to create 2 keys for the <request> node:

1) 1 key containing all the SomeTypeB nodes
2) 1 key containing all other nodes in request.

I would then process each key with a for-each statment. I wanted to be able to just create a template to handle all of this. The actual key can be defined at the top I tried that too. But I always felt that my key definition was not correct.

How would I define a key which would create a set of nodes for SomeTypeB and another key (I was thinking a negation of the other key) for all non-SomeTypeB nodes and then process them using-for each statement?

Since the code I inherited calls templates explicitly it does not have any apply-templetes statements which I'm still confused about their order of execution. Calling templates explicitly is easier for me to understand as it's like Java methodology which I'm much more comfortable with.

Again, I appreciate your quick responses and great help. You're helping me to really understand the workings of XSLT

J

jiggs · February 1st, 2009, 10:01 AM

Hi Martin,

Sorry to bother you again. The post of what I'm trying to do exactly was approved by the admins .. it's post #17. If you can give me some pointers on what to do that would be really helpful as I'm still stuck on this issue

Thanks!

J

Martin Honnen · February 1st, 2009, 12:26 PM

Here is a sample stylesheet that should create the described output:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
  exclude-result-prefixes="soapenv"
  version="1.0">
  
  <xsl:output method="xml" indent="yes"/>
  <xsl:strip-space elements="*"/>
  
  <xsl:key name="by-name" match="request/*/*/*" use="name()"/>
  
  <xsl:template match="/soapenv:Envelope">
    <StepData>
      <Flow>
        <ProcessClassID>AGHExtractProc</ProcessClassID>
        <xsl:apply-templates select="soapenv:Body/callFlowRequest/LocaleID"/>
      </Flow>
      <Variables>
        <xsl:apply-templates select="soapenv:Body"/>
      </Variables>
    </StepData>
  </xsl:template>
  
  <xsl:template match="LocaleID">
    <xsl:element name="{name()}">
      <xsl:value-of select="."/>
    </xsl:element>
  </xsl:template>
  
  <xsl:template match="soapenv:Body">
    <Group name="Body">
      <xsl:apply-templates/>
    </Group>
  </xsl:template>
  
  <xsl:template match="callFlowRequest">
    <Group name="callFlowRequest">
      <xsl:apply-templates select="User"/>
      <xsl:apply-templates select="request"/>
    </Group>
  </xsl:template>
  
  <xsl:template match="User">
    <Variable name="User">
      <Value>
        <xsl:value-of select="."/>
      </Value>
    </Variable>
  </xsl:template>
  
  <xsl:template match="request">
    <Group name="Request">
      <xsl:apply-templates select="*/*/*[generate-id() = generate-id(key('by-name', name())[1])]"/>
    </Group>
  </xsl:template>
  
  <xsl:template match="request/*/*/*">
    <Group name="{name()}">
      <xsl:choose>
        <xsl:when test="key('by-name', name())[2]">
          <xsl:apply-templates select="key('by-name', name())/*" mode="item"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:apply-templates select="*"/>
        </xsl:otherwise>
      </xsl:choose>
    </Group>
  </xsl:template>
  
  <xsl:template match="request/*/*/*/*" mode="item">
    <Item>
      <Variable name="{name()}">
        <Value>
          <xsl:value-of select="."/>
        </Value>
      </Variable>
     </Item>
   </xsl:template>
   
   <xsl:template match="request/*/*/*/*">
     <Variable name="{name()}">
       <Value>
         <xsl:value-of select="."/>
       </Value>
     </Variable>
   </xsl:template>
  
</xsl:stylesheet>

jiggs · February 2nd, 2009, 12:30 AM

Quote:

Originally Posted by Martin Honnen

Here is a sample stylesheet that should create the described output:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
  exclude-result-prefixes="soapenv"
  version="1.0">
 
  <xsl:output method="xml" indent="yes"/>
  <xsl:strip-space elements="*"/>
 
  <xsl:key name="by-name" match="request/*/*/*" use="name()"/>
 
  <xsl:template match="/soapenv:Envelope">
    <StepData>
      <Flow>
        <ProcessClassID>AGHExtractProc</ProcessClassID>
        <xsl:apply-templates select="soapenv:Body/callFlowRequest/LocaleID"/>
      </Flow>
      <Variables>
        <xsl:apply-templates select="soapenv:Body"/>
      </Variables>
    </StepData>
  </xsl:template>
 
  <xsl:template match="LocaleID">
    <xsl:element name="{name()}">
      <xsl:value-of select="."/>
    </xsl:element>
  </xsl:template>
 
  <xsl:template match="soapenv:Body">
    <Group name="Body">
      <xsl:apply-templates/>
    </Group>
  </xsl:template>
 
  <xsl:template match="callFlowRequest">
    <Group name="callFlowRequest">
      <xsl:apply-templates select="User"/>
      <xsl:apply-templates select="request"/>
    </Group>
  </xsl:template>
 
  <xsl:template match="User">
    <Variable name="User">
      <Value>
        <xsl:value-of select="."/>
      </Value>
    </Variable>
  </xsl:template>
 
  <xsl:template match="request">
    <Group name="Request">
      <xsl:apply-templates select="*/*/*[generate-id() = generate-id(key('by-name', name())[1])]"/>
    </Group>
  </xsl:template>
 
  <xsl:template match="request/*/*/*">
    <Group name="{name()}">
      <xsl:choose>
        <xsl:when test="key('by-name', name())[2]">
          <xsl:apply-templates select="key('by-name', name())/*" mode="item"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:apply-templates select="*"/>
        </xsl:otherwise>
      </xsl:choose>
    </Group>
  </xsl:template>
 
  <xsl:template match="request/*/*/*/*" mode="item">
    <Item>
      <Variable name="{name()}">
        <Value>
          <xsl:value-of select="."/>
        </Value>
      </Variable>
     </Item>
   </xsl:template>
 
   <xsl:template match="request/*/*/*/*">
     <Variable name="{name()}">
       <Value>
         <xsl:value-of select="."/>
       </Value>
     </Variable>
   </xsl:template>
 
</xsl:stylesheet>

Martin thank you very much on this! There is one final issue which my original input did not do a good job showing. For children of SomeTypeB the <Item> tags should be around them all not around each child:

Code:

<SomeTypeB>
   <Att1> A </Att1>
   <Att2> B </Att2>
</SomeTypeB>
<SomeTypeB>
   <Att1> A </Att1>
</SomeTypeB>

Therefore the output should be

Code:

<Group name = someTypeB>
    <Item>
          <Variable name = Att1>
                <Value> A </Value>
          <Variable name = Att2>
                <Value> B </Value>
     </Item>
     <Item>
             <Value> B </Value>
     </Item>
</Group>

I recogize your code groups together all children element of all <SomeTypeB> nodes and then processes them individually and applies the <Item> tags around each child. But like I note above I need all the children of each <SomeItemB> nodes to be under the same <Item> node but all overall <SomeItemB> nodes to be under the same Group.

I hope you're a Steleers fan and in good humour to help me out with this final contraption

. Even though I fully understand what your code is doing and how it's doing it I'm still not able to change it to fit my needs here.

In any case, you've been a world of help!

Best regards,
J

Martin Honnen · February 2nd, 2009, 11:53 AM

Here is an adapted stylesheet that should do what you want:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
  exclude-result-prefixes="soapenv"
  version="1.0">
  
  <xsl:output method="xml" indent="yes"/>
  <xsl:strip-space elements="*"/>
  
  <xsl:key name="by-name" match="request/*/*/*" use="name()"/>
  
  <xsl:template match="/soapenv:Envelope">
    <StepData>
      <Flow>
        <ProcessClassID>AGHExtractProc</ProcessClassID>
        <xsl:apply-templates select="soapenv:Body/callFlowRequest/LocaleID"/>
      </Flow>
      <Variables>
        <xsl:apply-templates select="soapenv:Body"/>
      </Variables>
    </StepData>
  </xsl:template>
  
  <xsl:template match="LocaleID">
    <xsl:element name="{name()}">
      <xsl:value-of select="."/>
    </xsl:element>
  </xsl:template>
  
  <xsl:template match="soapenv:Body">
    <Group name="Body">
      <xsl:apply-templates/>
    </Group>
  </xsl:template>
  
  <xsl:template match="callFlowRequest">
    <Group name="callFlowRequest">
      <xsl:apply-templates select="User"/>
      <xsl:apply-templates select="request"/>
    </Group>
  </xsl:template>
  
  <xsl:template match="User">
    <Variable name="User">
      <Value>
        <xsl:value-of select="."/>
      </Value>
    </Variable>
  </xsl:template>
  
  <xsl:template match="request">
    <Group name="Request">
      <xsl:apply-templates select="*/*/*[generate-id() = generate-id(key('by-name', name())[1])]"/>
    </Group>
  </xsl:template>
  
  <xsl:template match="request/*/*/*">
    <Group name="{name()}">
      <xsl:choose>
        <xsl:when test="key('by-name', name())[2]">
          <xsl:apply-templates select="key('by-name', name())" mode="item"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:apply-templates select="*"/>
        </xsl:otherwise>
      </xsl:choose>
    </Group>
  </xsl:template>
  
  <xsl:template match="request/*/*/*" mode="item">
    <Item>
      <xsl:apply-templates select="*"/>
    </Item>
  </xsl:template>
   
   <xsl:template match="request/*/*/*/*">
     <Variable name="{name()}">
       <Value>
         <xsl:value-of select="."/>
       </Value>
     </Variable>
   </xsl:template>
  
</xsl:stylesheet>

jiggs · February 3rd, 2009, 02:53 AM

The most gracious thank you Martin. You've been a world of help and my understanding of XSLT has greatly improved thanks to you - I tend to learn best by example.

J