XSLT Returns Too Much Data

Ozeroc · February 11th, 2009, 07:20 AM

Hello...

I'm trying to transform a complex xml document to a text file and I keep getting a lot of extra data in my output. The following is a sample of the xml:

Code:

 
<env:Envelope xmlns:env="http://schemas.xmlsoap.org/soap/envelope/"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:soapenc="http://schemas.xmlsoap.org/soap/encoding/"
xmlns:xsd="http://www.w3.org/2001/XMLSchema">
 <env:Header/>
 <env:Body>
  <m:getResponse xmlns:m="temp.temp1.temp2">
   <n1:data_result xmlns:n1="temp.temp1.temp2">
    <n2:aircraftModels xmlns:n2="java:temp.temp1.temp2.value" xsi:type="n2:ArrayOfAircraftModel">
     <n2:AircraftModel xsi:type="n2:AircraftModel">
      <n2:aircraftType>A1</n2:aircraftType>
     </n2:AircraftModel>
     <n2:AircraftModel xsi:type="n2:AircraftModel">
      <n2:aircraftType>A10</n2:aircraftType>
     </n2:AircraftModel>
    </n2:aircraftModels>
    <n3:fUnits xmlns:n3="java:temp.temp1.temp2.value" xsi:type="n3:ArrayOfFUnit"/>
    <n4:operatingLocations xmlns:n4="java:temp.temp1.temp2.value" xsi:type="n4:ArrayOfOperatingLocation">
     <n4:OperatingLocation>
      <n4:availabilities xsi:type="n4:ArrayOfAvailability"/>
      <n4:geodetic>
       <n5:datum xmlns:n5="java:temp.temp1.temp2.conversion">WRS84</n5:datum>
       <n6:height xmlns:n6="java:temp.temp1.temp2.conversion">0.0</n6:height>
       <n7:latitude xmlns:n7="java:temp.temp1.temp3.conversion">1234567890</n7:latitude>
       <n8:longitude xmlns:n8="java:temp.temp1.temp3.conversion">-1234567890</n8:longitude>
      </n4:geodetic>
     </n4:OperatingLocation>
   </n1:data_result>
  </m:getResponse>
 </env:Body>
</env:Envelope>

I have no control over the formatting of this data or the way namespaces are used within it. Here's my xslt:

Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
           xmlns:xs="http://www.w3.org/2001/XMLSchema"
           xmlns:fn="http://www.w3.org/2005/xpath-functions"
           xmlns:n2="java:temp.temp1.temp2.value">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>
 <xsl:template match="n2:aircraftModels">
  <xsl:for-each select="n2:AircraftModel">
   <xsl:value-of select="n2:aircraftType"/><xsl:text>
</xsl:text>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

And here's the result:

Code:

A1
A10
WRS840.01234567890-1234567890

As you can see the result is not what I was expecting. I'm thinking that the problem may be due to the namespaces or maybe the xsi:type attributes in the source xml. Thanks for any help you can provide!

Oz

mhkay · February 11th, 2009, 07:30 AM

You don't actually say what output you want.

The default template rule copies all the text of an element to the output. I think you want a default that doesn't copy the text. You can achieve this with the rule

<xsl:template match="*"/>

This has nothing to do with namespaces.

Ozeroc · February 11th, 2009, 08:42 AM

In this case I was just looking for a list of each aircraftType followed by a CR/LF so I expected to just see the following:

A1
A10

Instead it just keeps dumping all the text data found after the closing </n2:AircraftModel> tag. I'm using XMLSpy and I'll try your suggestion and let you know how it works. Thanks

Oz

Ozeroc · February 11th, 2009, 09:01 AM

Hmmm... I tried:

Code:

<xsl:template match="*">
  <xsl:for-each select="n2:AircraftModel">
   <xsl:value-of select="n2:aircraftType"/><xsl:text>
</xsl:text>
  </xsl:for-each>
 </xsl:template>

and it didn't return anything....

joefawcett · February 11th, 2009, 09:20 AM

It's not supposed to, it's a catch-all that means that any elements not matched specifically are to be ignored:

Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
           xmlns:xs="http://www.w3.org/2001/XMLSchema"
           xmlns:fn="http://www.w3.org/2005/xpath-functions"
           xmlns:n2="java:temp.temp1.temp2.value">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>
 <xsl:template match="n2:aircraftModel">  
   <xsl:value-of select="n2:aircraftType"/><xsl:text>
</xsl:text>
</xsl:template>
<xsl:template match="*"/>
</xsl:stylesheet>

Ozeroc · February 11th, 2009, 09:35 AM

Huh... That make's sense. But when I add that as you indicated above, I don't get any output whatsoever. O.o

Oz

joefawcett · February 11th, 2009, 09:37 AM

Try:

Code:


<xsl:stylesheetversion="2.0"xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:fn="http://www.w3.org/2005/xpath-functions"
xmlns:n2="java:temp.temp1.temp2.value">
<xsl:outputmethod="text"/>
<xsl:strip-spaceelements="*"/>
<xsl:templatematch="/">
<xsl:apply-templatesselect="//n2:AircraftModel" />
</xsl:template>
<xsl:templatematch="n2:AircraftModel">
<xsl:value-ofselect="n2:aircraftType"/>
<xsl:text>
</xsl:text>
</xsl:template>
<xsl:templatematch="*"/>
</xsl:stylesheet>

Ozeroc · February 11th, 2009, 09:57 AM

Wow! That completely worked. I guess I need to try to retrain my brain for dealing with XML. I so thought a for-each loop was the way to go here. Thanks for the help.

Oz