Returning PSV having headers once in whole parsing

dved · February 13th, 2009, 03:25 PM

Hi,

I am applying XSLT to multiple xmls. I want that XSLT returns names of the tag only once(pipe separated) with data values. for Eg.

<xsl:template match="root">
<xsl:for-each select="//*">
<xsl:value-of select="local-name()"/>|<xsl:value-of select="current()/text()"/>|
<xsl:text>
</xsl:text>
</xsl:for-each>
</xsl:template>

The above code returns me the names of the tag with values but i want names of tag only once.

so if I have an XML like :
<x>
<a>1</a>
<b>2</b>
<c>3</c>
</x>
<x>
<a>4</a>
<b>5</b>
<c>6</c>
</x>
The output should be like :
a|b|c|1|2|3|4|5|6|

Please help

mrame · February 16th, 2009, 03:04 AM

Try this:

Code:

 
<xsl:template match="/">
<xsl:variable name="child">
<xsl:value-of select="distinct-values(//*[. = text()]/local-name())"></xsl:value-of>
</xsl:variable>
<xsl:value-of select="translate($child, ' ', '|')"></xsl:value-of>
<xsl:for-each select="//*[. = text()]">
<xsl:if test="position() = 1">
<xsl:text>|</xsl:text>
</xsl:if>
<xsl:value-of select="."></xsl:value-of>
<xsl:if test="position() != last()">
<xsl:text>|</xsl:text>
</xsl:if>
</xsl:for-each>
</xsl:template>

mhkay · February 16th, 2009, 06:23 AM

Your example output suggests that you actual requirement is something like "Show the names and values of all the elements that have no element children, eliminating duplicates". In XSLT 2.0 that is

<xsl:template match="/">
<xsl:value-of select="distinct-values(//*[not(*)]/(name(.), string(.)))" separator="|"/>
</xsl:template>

In XSLT 1.0 it's going to be MUCH more complicated.

dved · February 18th, 2009, 11:36 AM

Well what I m trying to do is I want to extract the names of the tag only once in whole parsing so that I can treat them as column header while creating my CSV.

this is what I m trying to write but it does not work:

<xsl:template match="paymentHistoryList" >
<xsl:apply-templates ></xsl:apply-templates>
</xsl:template>
<!--This part is what I m interested in..--!>
<xsl:template match="paymentHistoryInfo" >
<xsl:for-each select="*/paymentHistoryList/*">
<xsl:value-of select="local-name()"/>
<xsl:value-of select="'|'"/>
</xsl:for-each>
&NL;

</xsl:template>

<!--This works well --!>
<xsl:template match="paymentHistoryInfo">

<xsl:for-each select="*">
<xsl:value-of select="."/>
<xsl:choose>
<xsl:when test="position() != last()">
<xsl:value-of select="'|'"/>
</xsl:when>
<xsl:when test="position() = last()">
&NL;
</xsl:when>
</xsl:choose>

</xsl:for-each>

</xsl:template>

MY XML is like this:

<serviceHeader>
<billingSys>VISION_EAST</billingSys>
<clientId>VZW-FIN</clientId>
<userId>00000003</userId>
<password>01VISION</password>
<serviceName>PaymentHistoryInquiry</serviceName>
<statusCode>00</statusCode>
<errorCode>00</errorCode>
<errorMsg/>
<cicsErrorCode>00</cicsErrorCode>
<serverName>vmwdev2</serverName>
<correlationId>c48e6a2ad3c47cc5:-2cb74c38:11f810f0494:-7a85:vmwdev2:DVSCOMMON</correlationId>
</serviceHeader>
<serviceBody>
<serviceRequest>
<accountNo>15241-1</accountNo>
</serviceRequest>
<serviceResponse>
<paymentHistoryRowCount>100</paymentHistoryRowCount>
<paymentHistoryList>
<paymentHistoryInfo>
<invoiceDate>200812</invoiceDate>
<invoiceNumber>1493001562</invoiceNumber>
<previousBalance>84.91</previousBalance>
<paymentsRecieved>84.91</paymentsRecieved>
<balanceForward>0.0</balanceForward>
<currentCharges>83.96</currentCharges>
<totalBalance>83.96</totalBalance>
</paymentHistoryInfo>
<paymentHistoryInfo>
<invoiceDate>200811</invoiceDate>
<invoiceNumber>1482401248</invoiceNumber>
<previousBalance>173.66</previousBalance>
<paymentsRecieved>173.66</paymentsRecieved>
<balanceForward>0.0</balanceForward>
<currentCharges>84.91</currentCharges>
<totalBalance>84.91</totalBalance>
</paymentHistoryInfo>
</paymentHistoryList>
</serviceResponse>
</serviceBody>
</service>

Martin Honnen · February 18th, 2009, 01:26 PM

Here is an XSLT 1.0 stylesheet that outputs the names of child elements in a header line, then the values in following lines:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  
  <xsl:output method="text"/>
  
  <xsl:param name="nl" select="'
'"/>
  <xsl:param name="sep" select="'|'"/>
  
  <xsl:template match="/">
    <xsl:apply-templates select="service/serviceBody/serviceResponse/paymentHistoryList/paymentHistoryInfo[1]/*" mode="header"/>
    <xsl:apply-templates select="service/serviceBody/serviceResponse/paymentHistoryList/paymentHistoryInfo"/>
  </xsl:template>
  
  <xsl:template match="paymentHistoryInfo/*" mode="header">
    <xsl:value-of select="local-name()"/>
    <xsl:choose>
      <xsl:when test="position() != last()">
        <xsl:value-of select="$sep"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$nl"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
  
  <xsl:template match="paymentHistoryInfo">
    <xsl:apply-templates select="*"/>
  </xsl:template>

  <xsl:template match="paymentHistoryInfo/*" >
    <xsl:value-of select="."/>
    <xsl:choose>
      <xsl:when test="position() != last()">
        <xsl:value-of select="$sep"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$nl"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

When applied to the input document

Code:

<?xml version="1.0" encoding="utf-8" ?>
<service>
  <serviceHeader>
    <billingSys>VISION_EAST</billingSys>
    <clientId>VZW-FIN</clientId>
    <userId>00000003</userId>
    <password>01VISION</password>
    <serviceName>PaymentHistoryInquiry</serviceName>
    <statusCode>00</statusCode>
    <errorCode>00</errorCode>
    <errorMsg/>
    <cicsErrorCode>00</cicsErrorCode>
    <serverName>vmwdev2</serverName>
    <correlationId>c48e6a2ad3c47cc5:-2cb74c38:11f810f0494:-7a85:vmwdev2:DVSCOMMON</correlationId>
  </serviceHeader>
  <serviceBody>
    <serviceRequest>
      <accountNo>15241-1</accountNo>
    </serviceRequest>
    <serviceResponse>
      <paymentHistoryRowCount>100</paymentHistoryRowCount>
      <paymentHistoryList>
        <paymentHistoryInfo>
          <invoiceDate>200812</invoiceDate>
          <invoiceNumber>1493001562</invoiceNumber>
          <previousBalance>84.91</previousBalance>
          <paymentsRecieved>84.91</paymentsRecieved>
          <balanceForward>0.0</balanceForward>
          <currentCharges>83.96</currentCharges>
          <totalBalance>83.96</totalBalance>
        </paymentHistoryInfo>
        <paymentHistoryInfo>
          <invoiceDate>200811</invoiceDate>
          <invoiceNumber>1482401248</invoiceNumber>
          <previousBalance>173.66</previousBalance>
          <paymentsRecieved>173.66</paymentsRecieved>
          <balanceForward>0.0</balanceForward>
          <currentCharges>84.91</currentCharges>
          <totalBalance>84.91</totalBalance>
        </paymentHistoryInfo>
      </paymentHistoryList>
    </serviceResponse>
  </serviceBody>
</service>

the output is as follows:

Code:

invoiceDate|invoiceNumber|previousBalance|paymentsRecieved|balanceForward|currentCharges|totalBalance
200812|1493001562|84.91|84.91|0.0|83.96|83.96
200811|1482401248|173.66|173.66|0.0|84.91|84.91

dved · February 19th, 2009, 03:11 PM

Thanks for that..got it..