XSLT/XPath: How to display single node occurence

kwilliams · March 17th, 2009, 10:20 AM

Hello,

I'm working on a for-each element that will display only one occurrence of a name node, even if there are several occurences of that name in the XML doc. Here's an example of what I need:

XML doc:
<root>
<name>Janice Smith</name>
<name>Janice Smith</name>
<name>Michael Jones</name>
<name>Michael Jones</name>
<name>Michael Jones</name>
</root>

XSLT FOR-EACH ELEMENT:
<xsl:for-each select="root/name">
<xsl:value-of select="." /><br />
</xsl:for-each>

WANTED RESULT:
Janice Smith
Michael Jones

I'll continue to work on a possible solution until/if I hear get from someone else. Thanks for any help.

Martin Honnen · March 17th, 2009, 10:30 AM

Well in XSLT 2.0 it is easy with the distinct-values function:

Code:

    <xsl:for-each select="distinct-values(root/name)">
      <xsl:value-of select="."/>
      <br/>
    </xsl:for-each>

Or you could use xsl:for-each-group select="root/name" group-by=".".

With XSLT 1.0 you could use Muenchian grouping. Let us know if you need help with that.

kwilliams · March 17th, 2009, 10:33 AM

Thanks Martin,

I'm currently using 1.0, so I can't use that cool distinct-values function. I need to upgrade sometime soon so that I can utilize all of those functions.

Anyway, I was able to come up with a solution that works in 1.0, and here it is:

<xsl:for-each select="root/name[not(text() = ../preceding-sibling::name/text())]">

...and it worked great. Thanks again for your help!

Martin Honnen · March 17th, 2009, 10:42 AM

Using Muenchian grouping should be more efficient for large data:

Code:

  <xsl:key name="k1" match="name" use="."/>
  
  <xsl:template match="/">
    <xsl:for-each select="root/name[generate-id() = generate-id(key('k1', .)[1])]">
      <xsl:value-of select="."/>
      <br/>
    </xsl:for-each>
  </xsl:template>