Preserve prefix namespaces from source document

Marcela Sobrinho · April 17th, 2009, 08:57 AM

Hi,

I am trying to write a xsl that renames an element. Let's say that I changed the element name at the XML Schema and want to change it in all the XML instances that I have. This would be a really simple task if there is no namespace present.
But when there is I am having the follwing problem:
-If I need to change <name:something> to <name:anything>, knowing what is the uri that is represented by name. For writing in the output somthing like: <name:something> I need to declare in the xsl the prefix name in the xsl.
But I can not know which prefixes the source is using ( each xml docuent can use a different prefix for the same url and I wouldn't want to change the original prefix).
I can obtain the prefix used in the source using fn:prefix-from-QName(fn:node-name(.)), but I am not able to declare this namespace dynamically.

Does anyone knows how to solve this problem?

Thanks

mhkay · April 17th, 2009, 09:13 AM

You haven't made your requirements clear. Are you saying you want to change the local name, but keep the prefix and namespace URI the same? If so you can try

<xsl:element name="newname" namespace="{namespace-uri(.)}">

and if you're lucky the system will keep the prefix, or if you want better certainty you can do

<xsl:element name="{substring-before(name(.), ':')}:newname" namespace="{namespace-uri(.)}">

Remember that prefixes don't really matter, it's only the namespace URI that's important.

Martin Honnen · April 17th, 2009, 09:20 AM

What matters in your XSLT stylesheet is the namespace URI, not the prefix. So to change 'foo' elements in the namespace 'http://example.com/ns1' to 'bar' elements in the same namespace you can use e.g.

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0"
  xmlns:pf="http://example.com/ns1"
  exclude-result-prefixes="pf">

  <xsl:template match="pf:foo">
    <xsl:element name="{if (prefix-from-QName(node-name(.))) then concat(prefix-from-QName(node-name(.)), ':') else ''}bar " namespace="{namespace-uri()}">
       <xsl:apply-templates select="@* | node()"/>
    </xsl:element>
  </xsl:template>
  
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

Marcela Sobrinho · April 17th, 2009, 09:28 AM

This works, thanks.