Sequencing a XML file

chandra_perni · May 11th, 2009, 05:29 AM

Hi I have a requirement where I need to restructure the XML file using the xsl sort based on the attribute. sno is the attribute i am using.

My input xml is
----------------
<emp>

<emp1 sno="8">
<name>Chandra</name>
<country>India</country>
<company>B</company>
<dept>
<deptno>6</deptno>
<deptname>Dev</deptname>
</dept>
</emp1>
<emp2 sno="7">
<name>Vijay</name>
<country>Australia</country>
<company>C</company>
<dept>
<deptno>1</deptno>
<deptname>RND</deptname>
</dept>
</emp2>

</emp>

My Output xml requirement is as follows:
---------------------------------------
<emp>
<emp2>
<name>Vijay</name>
<country>Australia</country>
<company>C</company>
<dept>
<deptno>1</deptno>
<deptname>RND</deptname>
</dept>
</emp2>
<emp1>
<name>Chandra</name>
<country>India</country>
<company>B</company>
<dept>
<deptno>6</deptno>
<deptname>Dev</deptname>
</dept>
</emp1>
</emp>

I am not able to get the root element but able to acheive

<emp2>
<name>Vijay</name>
<country>Australia</country>
<company>C</company>
<dept>
<deptno>1</deptno>
<deptname>RND</deptname>
</dept>
</emp2>
<emp1>
<name>Chandra</name>
<country>India</country>
<company>B</company>
<dept>
<deptno>6</deptno>
<deptname>Dev</deptname>
</dept>
</emp1>

My xsl code:
-------------
<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<xsl:for-each select="//*[@sno]">
<xsl:sort select="@sno"/>
<xsl:variable name="temp">
<xsl:value-of select="local-name()"/>
</xsl:variable>
<xsl:element name="{$temp}">
<xsl:apply-templates/>
</xsl:element>
</xsl:for-each>
</xsl:template>
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>

Please suggest.

mhkay · May 11th, 2009, 05:47 AM

Firstly, it's a very strange use of XML for each employee to have a different element name. If you have any influence over the design, get this changed.

It's simple to add a wrapper element:

<xsl:template match="/">
<emp>
<xsl:for-each ...

</xsl:for-each>
</emp>
</xsl:template>

mrame · May 11th, 2009, 05:50 AM

Try this:

Code:

<xsl:template match="/">
<emp>
<xsl:for-each select="//*[@sno]">
<xsl:sort select="@sno"/>
<xsl:variable name="temp">
<xsl:value-of select="local-name()"/>
</xsl:variable>
<xsl:element name="{$temp}">
<xsl:apply-templates/>
</xsl:element>
</xsl:for-each>
</emp>
</xsl:template>

<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>

chandra_perni · May 11th, 2009, 07:57 AM

Hi Michael thanks for the reply. In the above suggestion we are hardcoding the root element but i dont want to do that because i want to identify the parent instead of hardcoding. can you plz suggest that?

Actually this is a prototype that i am trying to solve original requirement. We have an input xml file coming in an order different to defined XSD. So we will will sequence this xml file to correct order of the xsd before giving input to webservice as the validation fails otherwise. In my xsl file by adding the attribute keys [sno is the attribute in the above prototype] and sort based on the attribute key. Can you suggest an alternate approach. Also other approach i am giving it a try is to parse the XML file using the DOM Parser.

Thank you.

Martin Honnen · May 11th, 2009, 08:34 AM

Where do you want to take the root element from? From the input element? Then simply copy it over e.g.

Code:

<xsl:template match="/*">
  <xsl:copy>
    <xsl:apply-templates select="*">
      <xsl:sort select="@sno"/>
    </xsl:apply-templates>
  </xsl:copy>
</xsl:template>

<xsl:template match="@*|node()">
               <xsl:copy>
                       <xsl:apply-templates select="@*|node()"/>
               </xsl:copy>
      </xsl:template>

chandra_perni · May 11th, 2009, 09:15 AM

Hi Martin yes I want to take the root element from the input element. This is fine but in this we will be printing the attributes also. But in my actual xsd there will be no attribute for the elements [i mean sno] so validation fails. I will be assigning it in my input xml only for sorting purpose. So i want my output xml to be

<emp>
<emp2>
<name>Vijay</name>
<country>Australia</country>
<company>C</company>
<dept>
<deptno>1</deptno>
<deptname>RND</deptname>
</dept>
</emp2>
...
</emp>

Martin Honnen · May 11th, 2009, 09:24 AM

If you do not want to copy the 'sno' attributes then add a template

Code:

<xsl:template match="/*/*/@sno"/>

which suppresses copying those attributes.

chandra_perni · May 11th, 2009, 09:32 AM

Thank you very much Martin I am able to acheive my desired output.