XSLT for displaying XML data in list order

kvishnu · May 11th, 2009, 07:57 AM

Hi all,
i have the XML like this:
<Root>
<MainHeading>TESTING XSLT</MainHeading>
<boby>
<id>1</id>
<heading>Name</heading>
<detail>This is name of user</detail>
</body>
<boby>
<id>2</id>
<heading>Address</heading>
<detail>This is address of user</detail>
</body>
<boby>
<id>3</id>
<heading>Phones</heading>
<detail>
<inner>Home </inner>
<inner>Office</inner>
<inner>Personnel</inner>
</detail>
</body>
</Root>

how can i write XSLT for this xml to that in the following manner

TESTING XSLT
Name

This is name of user

Address

This is address of user

Phones

Home
Office
Personnel

Please show me the way, To get the solution whether
i have to change the xml or not.?

Martin Honnen · May 11th, 2009, 08:27 AM

Assuming you want to transform your XML to HTML with heading (h1, h2) and list (ul, li) elements then here is a stylesheet:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  
  <xsl:output method="html" indent="yes"/>
  <xsl:strip-space elements="*"/>
  
  <xsl:template match="/Root">
    <html>
      <head>
        <title>Example</title>
      </head>
      <body>
        <xsl:apply-templates/>
      </body>
    </html>
  </xsl:template>
  
  <xsl:template match="MainHeading">
    <h1>
      <xsl:apply-templates/>
    </h1>
  </xsl:template>
  
  <xsl:template match="body">
    <div>
      <xsl:apply-templates select="heading | detail"/>
    </div>
  </xsl:template>
  
  <xsl:template match="body/heading">
    <h2>
      <xsl:apply-templates/>
    </h2>
  </xsl:template>
  
  <xsl:template match="body/detail">
    <ul>
      <xsl:apply-templates/>
    </ul>
  </xsl:template>
  
  <xsl:template match="body/detail//text()">
    <li>
      <xsl:value-of select="."/>
    </li>
  </xsl:template>

</xsl:stylesheet>