XSLT 1.0 sort issue

Martin Honnen · June 12th, 2009, 11:25 AM

Once you have a first and last name element you can then easily sort:

Code:

  <xsl:template match="students">
    <xsl:variable name="students">
      <xsl:apply-templates select="student" mode="change"/>
    </xsl:variable>
    <xsl:apply-templates select="exsl:node-set($students)/student">
      <xsl:sort select="first"/>
      <xsl:sort select="last"/>
    </xsl:apply-templates>
  </xsl:template>

JohnBampton · June 12th, 2009, 11:52 AM

Hi Martin,

In your code you have

Code:

<xsl:template match="stundent/*" mode="change">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

The "stundent/*" must be a typo right?

If so then this stylesheet is just a different identity transform??

I figured out the sorting. Thanks. It had to be name/first and name/last

Please correct me if I am wrong. I appreciate all the help you have provided. Thanks

Martin Honnen · June 12th, 2009, 11:58 AM

The code in the last post is slightly wrong, you need

Code:

  <xsl:template match="students">
    <xsl:variable name="students">
      <xsl:apply-templates select="student" mode="change"/>
    </xsl:variable>
    <xsl:apply-templates select="exsl:node-set($students)/student">
      <xsl:sort select="name/first"/>
      <xsl:sort select="name/last"/>
    </xsl:apply-templates>
  </xsl:template>

If you need to restore the original studentName element then you need to do that when processing the sorted student elements in your templates.

Martin Honnen · June 12th, 2009, 12:02 PM

Sorry about the typo, here is a corrected version:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0"
  xmlns:exsl="http://exslt.org/common"
  xmlns:str="http://exslt.org/strings"
  exclude-result-prefixes="exsl str">
  
  <xsl:template match="students">
    <xsl:variable name="students">
      <xsl:apply-templates select="student" mode="change"/>
    </xsl:variable>
    <xsl:apply-templates select="exsl:node-set($students)/student">
      <xsl:sort select="name/first"/>
      <xsl:sort select="name/last"/>
    </xsl:apply-templates>
  </xsl:template>
  
  <xsl:template match="student" mode="change">
    <xsl:copy>
      <xsl:apply-templates mode="change"/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:template match="student/studentName" mode="change" priority="2">
    <xsl:variable name="comp" select="str:tokenize(translate(., ', ', '||'), '|')"/>
    <name>
      <first>
        <xsl:for-each select="$comp[position() != last()]">
          <xsl:value-of select="."/>
          <xsl:if test="position() != last()"><xsl:text> </xsl:text></xsl:if>
        </xsl:for-each>
      </first>
      <last>
        <xsl:value-of select="$comp[last()]"/>
      </last>
    </name>
  </xsl:template>
  
  <xsl:template match="student/*" mode="change">
    <xsl:copy>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:template match="student">
    <!-- process, this example simply copies -->
    <xsl:copy-of select="."/>
  </xsl:template>

</xsl:stylesheet>

JohnBampton · June 12th, 2009, 12:17 PM

That works. But now for the hard part. I want now want to output HTML something like

<xsl:for-each student>
"sorted"
<tr>
<td rowspan="2">
<img src ="{normalize-space(studentPhoto/path)}"></img>
</td>
<td >
<xsl:value-of select="concat(first,' ',last)">
</td>
</tr>
<tr>
<td>
<xsl:value-of select="studentLink"/>
</td>
</tr>
</xsl:for-each>

I can't seem to adapt your solution to do this.

Regards

Martin Honnen · June 12th, 2009, 12:26 PM

This should help:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0"
  xmlns:exsl="http://exslt.org/common"
  xmlns:str="http://exslt.org/strings"
  exclude-result-prefixes="exsl str">
  
  <xsl:output method="html" indent="yes"/>
  
  <xsl:template match="students">
    <xsl:variable name="students">
      <xsl:apply-templates select="student" mode="change"/>
    </xsl:variable>
    <xsl:for-each select="exsl:node-set($students)/student">
      <xsl:sort select="name/first"/>
      <xsl:sort select="name/last"/>

      <tr>
      <td rowspan="2">
      <img src="{normalize-space(studentPhoto/path)}"></img>
      </td>
      <td>
      <xsl:value-of select="concat(name/first,' ',name/last)"/>
      </td>
      </tr>
      <tr>
      <td>
      <xsl:value-of select="studentLink"/>
      </td>
      </tr>
    </xsl:for-each>
  </xsl:template>
  
  <xsl:template match="student" mode="change">
    <xsl:copy>
      <xsl:apply-templates mode="change"/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:template match="student/studentName" mode="change" priority="2">
    <xsl:variable name="comp" select="str:tokenize(translate(., ', ', '||'), '|')"/>
    <name>
      <first>
        <xsl:for-each select="$comp[position() != last()]">
          <xsl:value-of select="."/>
          <xsl:if test="position() != last()"><xsl:text> </xsl:text></xsl:if>
        </xsl:for-each>
      </first>
      <last>
        <xsl:value-of select="$comp[last()]"/>
      </last>
    </name>
  </xsl:template>
  
  <xsl:template match="student/*" mode="change">
    <xsl:copy>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>
  
</xsl:stylesheet>

samjudson · June 12th, 2009, 12:27 PM

That's not hard at all - you just need to put whatever you want in the last template:

Code:

<xsl:template match="student">
    <!-- process, this example simply copies -->
    <tr>                    
    <td rowspan="2">
        <img src ="{normalize-space(studentPhoto/path)}"></img>
    </td>
    <td >
        <xsl:value-of select="concat(first,' ',last)">
    </td>
</tr>
<tr>                
    <td>
        <xsl:value-of select="studentLink"/>
    </td>
</tr>
  </xsl:template>

JohnBampton · June 12th, 2009, 12:45 PM

Code:

<tr>
            <td rowspan="2">
                <img src="{normalize-space(studentPhoto/path)}"></img>
            </td>
            <td>
                <xsl:value-of select="concat(name/first,' ',name/last)"/>
            </td>
        </tr>
        <tr>
            <td>
                <xsl:value-of select="studentLink"/>
            </td>
        </tr>

Thanks for your help, but I cannot seem to get the path and the studentlink to show??

Martin Honnen · June 12th, 2009, 12:59 PM

We are getting closer :). Try

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0"
  xmlns:exsl="http://exslt.org/common"
  xmlns:str="http://exslt.org/strings"
  exclude-result-prefixes="exsl str">
  
  <xsl:output method="html" indent="yes"/>
  
  <xsl:template match="students">
    <xsl:variable name="students">
      <xsl:apply-templates select="student" mode="change"/>
    </xsl:variable>
    <xsl:for-each select="exsl:node-set($students)/student">
      <xsl:sort select="name/first"/>
      <xsl:sort select="name/last"/>

      <tr>
      <td rowspan="2">
      <img src="{normalize-space(studentPhoto/path)}"></img>
      </td>
      <td>
      <xsl:value-of select="concat(name/first,' ',name/last)"/>
      </td>
      </tr>
      <tr>
      <td>
      <xsl:value-of select="studentLink"/>
      </td>
      </tr>
    </xsl:for-each>
  </xsl:template>
  
  <xsl:template match="student" mode="change">
    <xsl:copy>
      <xsl:apply-templates mode="change"/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:template match="student/studentName" mode="change" priority="2">
    <xsl:variable name="comp" select="str:tokenize(translate(., ', ', '||'), '|')"/>
    <name>
      <first>
        <xsl:for-each select="$comp[position() != last()]">
          <xsl:value-of select="."/>
          <xsl:if test="position() != last()"><xsl:text> </xsl:text></xsl:if>
        </xsl:for-each>
      </first>
      <last>
        <xsl:value-of select="$comp[last()]"/>
      </last>
    </name>
  </xsl:template>
  
  <xsl:template match="student/*" mode="change">
    <xsl:copy-of select="."/>
  </xsl:template>
  
</xsl:stylesheet>

JohnBampton · June 12th, 2009, 01:03 PM

Brilliant thanks guys! :)