Converting an XML doc to XSLT

xsltguy · July 24th, 2009, 01:46 PM

Hi all -

Need help in converting a flat XML doc to a nested XML structure using XSLT. I took a first pass at this. After this I am kind of stuck. Please let me know how to proceed further.

Source XML:

<data>
<row>
<id>200</id>
<level1>4000</level1>
<level2>26000</level2>
</row>
<row>
<id>200</id>
<level1>4000</level1>
<level2>16000</level2>
</row>
</data>

Output XML:
<data>

<node>
<id>200</id>
<level1>
<id>4000</id>
<level2>
<id>26000</id>
</level2>
<level2>
<id>16000</id>
</level2>
</level1>

</node>
</data>

And the XSLT I came up with that works for level1 only. Not sure how to get level2 though:

xsl:stylesheet xmlns:xsl = "http://www.w3.org/1999/XSL/Transform" version = "2.0" >
<xsl:key name="records" match="row" use="id" />
<xsl:template match="data">
<data>

<xsl:for-each select="row[generate-id() = generate-id(key('records',
id)[1])]">
<id><xsl:value-of select="id" /></id>

<xsl:for-each select="key('records', id)">
<level1><xsl:value-of select="level1" /></level1>
</xsl:for-each>
</xsl:for-each>
</data>
</xsl:template>

</xsl:stylesheet>

Any suggestions would be of great help

Thanks
K

Martin Honnen · July 24th, 2009, 02:00 PM

Here is an XSLT 2.0 solution working for two levels using for-each-group. If you have more levels then it makes sense to write a recursive function.

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">
  
  <xsl:output indent="yes"/>
  
  <xsl:template match="data">
    <xsl:copy>
      <xsl:for-each-group select="row" group-by="id">
        <node>
          <xsl:copy-of select="id"/>
          <xsl:for-each-group select="current-group()" group-by="level1">
            <level1>
              <id><xsl:value-of select="level1"/></id>
              <xsl:for-each-group select="current-group()" group-by="level2">
                <level2>
                  <id><xsl:value-of select="level2"/></id>
                </level2>
              </xsl:for-each-group>
            </level1>
          </xsl:for-each-group>
        </node>
      </xsl:for-each-group>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

xsltguy · July 24th, 2009, 02:34 PM

wow, that's simple. Wondering what would be the efficiency of the transformation on a large input dataset. The dataset would typically be the output of a stored procedure which is going to be flat.

Just curious. Thanks
K

mhkay · July 24th, 2009, 05:17 PM

The technique you used in your post is called Muenchian grouping, and it's the appropriate solution if you're stuck with an XSLT 1.0 processor. But I think you want to output the level1 outside the inner for-each, and the level2 inside it.

Martin's solution is much better if you've got XSLT 2.0 available.

As for efficiency, both solutions are likely to use indexes or hash tables internally and therefore be pretty scaleable.