XSLT Template

oornelas_Ca · August 14th, 2009, 05:08 PM

Using an XSLT Template, how can I modify all "property" elements so that these are change from this:

<property name="OnEmergency" type="System.Boolean" assembly="mscorlib, Version=2.0.0.0, Culture=neutral, PublicKeyToken=b77a5c561934e089">False</property>

To something like this:
<OnEmergency>False</OnEmergency>

Basically, I need to replace the element name with the value in the "name" attribute. Then, all attributes need to be removed.

Thanks,

mhkay · August 14th, 2009, 05:14 PM

Code:

<xsl:template match="property">
  <xsl:element name="{@name}">
    <xsl:value-of select="."/>
  </xsl:element>
</xsl:template>

oornelas_Ca · August 14th, 2009, 05:29 PM

The code snippet replaces only the top level "property" items, my bad, I did not specified that there are elements within elements (in many sub-levels) that are also named "property". Also, the following error is thrown:

"Only one top level element is allowed in an XML document"

I tried adding "<root>....</root>" but did not get rid off the error message.

Thanks,

mhkay · August 14th, 2009, 05:38 PM

Well to handle nested property elements just do xsl:apply-templates instead of xsl:value-of select=".", to recurse down the tree in the usual way.

If your output has more than one root element then outputting an element node from the match="/" template should fix it.

oornelas_Ca · August 14th, 2009, 06:10 PM

First of all, thanks for the great quick replies.

Still, something is missing, here is what I used as template:

<xsl:template match="/">
<xsl:element name="{@name}">
<xsl:apply-templates />
</xsl:element>
</xsl:template>

Here is what I got:
The empty string '' is not a valid name.

==================

My Source is this:
<?xml version="1.0" encoding="utf-8"?>
<object name="Inventory">
<properties>
<property name="Summary">
<properties>
<property name="StockABC" type="System.Int32">123</property>
<property name="StockABC" type="System.Int32">223</property>
</properties>
</property>
</properties>
</object>

=======================

The desire Output is this:

<?xml version="1.0" encoding="utf-8"?>
<Inventory>
<properties>
<Summary name="Summary">
<properties>
<StockABC>123</StockABC>
<StockABC>223</StockABC>
</properties>
</Summary>
</properties>
</Inventory>

Thanks,

oornelas_Ca · August 14th, 2009, 07:54 PM

The desire Output is this:

<?xml version="1.0" encoding="utf-8"?>
<Inventory>
<properties>
<Summary>
<properties>
<StockABC>123</StockABC>
<StockABC>223</StockABC>
</properties>
</Summary>
</properties>
</Inventory>

Martin Honnen · August 15th, 2009, 06:56 AM

The following two templates should suffice:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  
  <xsl:template match="node()">
    <xsl:copy>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:template match="property[@name] | object[@name]">
    <xsl:element name="{@name}">
      <xsl:apply-templates/>
    </xsl:element>
  </xsl:template>

</xsl:stylesheet>

mhkay · August 15th, 2009, 10:11 AM

In a template with match="/", the context node is the document root. Then @name refers to an attribute of the document node, which doesn't exist, so you are trying to create an element with no name. You should only use <element name="{@name}"> when you know the context node will have a name attribute and when you know it will be a valid element name.