GETTING COUNT AND POSITION using XSLT

Martin Honnen · August 18th, 2009, 08:31 AM

Here is an XSLT 1.0 solution, based on your original problem description:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  
  <xsl:output indent="yes"/>
  
  <xsl:template match="root">
    <rss>
      <xsl:apply-templates select="item"/>
    </rss>
  </xsl:template>
  
  <xsl:template match="item">
    <xsl:copy>
      <position>
        <xsl:value-of select="count(preceding-sibling::item[data[@name = 'title'] = current()/data[@name = 'title']]) + 1"/>
      </position>
      <total>
        <xsl:value-of select="count(../item[data[@name = 'title'] = current()/data[@name = 'title']])"/>
      </total>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

The following should have the same result but should be more efficient:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  
  <xsl:output indent="yes"/>
  
  <xsl:key name="k1" match="item" use="data[@name = 'title']"/>
  
  <xsl:template match="root">
    <rss>
      <xsl:apply-templates select="item"/>
    </rss>
  </xsl:template>
  
  <xsl:template match="item">
    <xsl:copy>
      <position>
        <xsl:value-of select="count(preceding-sibling::item[data[@name = 'title'] = current()/data[@name = 'title']]) + 1"/>
      </position>
      <total>
        <xsl:value-of select="count(key('k1', data[@name = 'title']))"/>
      </total>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

udaybob · August 18th, 2009, 07:33 PM

Hi Martin

Thank you for your response. I really appriciate it.
However iam not able to save the below code in xml spy.

<xsl:value-of select="count(preceding-sibling::item[data[@name = 'title'] = current()/data[@name = 'title']]) + 1"/>

i suspect on the square backets.syntactically some thing is wrong here.

Thanks
Uday

mhkay · August 19th, 2009, 04:44 AM

The syntax of

<xsl:value-of select="count(preceding-sibling::item[data[@name = 'title'] = current()/data[@name = 'title']]) + 1"/>

is correct. It compiles fine in Saxon.

Martin Honnen · August 19th, 2009, 06:09 AM

Quote:

Originally Posted by udaybob

However iam not able to save the below code in xml spy.

<xsl:value-of select="count(preceding-sibling::item[data[@name = 'title'] = current()/data[@name = 'title']]) + 1"/>

i suspect on the square backets.syntactically some thing is wrong here.

I tested the posted code successfully so I am not sure why you say XML Spy complains about the syntax.

udaybob · August 19th, 2009, 11:25 AM

Sorry guys..My bad. Its working fine.Thank you soo much for your contribution.

Can i stick to this forum for xslt 1.0 quires. Or is this place for only for 2.0 version??

Thanks mhkay and Martin Honnen

Uday

mhkay · August 19th, 2009, 11:37 AM

You're welcome to post XSLT 1.0 question here. But as with any question, there is no guarantee anyone will answer.

(Some of us - I speak for myself - simply don't find it very interesting to solve problems in XSLT 1.0 when the 2.0 solution is so much easier. Sorry, but we can choose which questions we want to answer - it's a service that relies entirely on volunteers.)

udaybob · August 19th, 2009, 01:34 PM

Thank you. I can understand. For now we are working on xslt 1.0. We have plans of migrating to 2.0 in future.

Thanks
Uday