XSLT output path route

chameleon · October 3rd, 2009, 07:52 AM

the XML file:

Code:

<?xml .....
<app name="A" path="">
   <app name="B" path="p1">
      <app name="C" path="p2" />
      <app name="D" path="p3" />
   </app>
   <app name="E" path="p4" />
</app>

Then in XSLT file I set with javascript a variable path="p2":

Code:

<xsl:variable name="path" select="'p2'" />

How can I get with XSLT a path route like this:
A :: B :: C <- this is output of XSLT

I am totally confused but I am sure XSLT can do this.

Martin Honnen · October 3rd, 2009, 08:00 AM

You can simply process the ancestor-or-self:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  
  <xsl:output method="text"/>
  
  <xsl:param name="path" select="'p2'"/>
  
  <xsl:template match="/">
    <xsl:for-each select="//app[@path = $path]/ancestor-or-self::app/@name">
      <xsl:value-of select="."/>
      <xsl:if test="position() != last()"> :: </xsl:if>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

mhkay · October 3rd, 2009, 11:03 AM

It's even easier in XSLT 2.0:

<xsl:value-of select="//app[@path = $path]/ancestor-or-self::app/@name"
separateor=" :: "/>

chameleon · October 3rd, 2009, 11:09 AM

Wow!
It works perfect.
I was not aware of ancestor-or-self.
Thanks.