Display keyword in different color in html

rangeshram · October 31st, 2009, 04:11 AM

Hi,

We're eager to know that is it possible to find specific word ("Ordinance" in this case) in the footnote element in xml file and using xslt apply color in html.

Input:

Code:

<?xml version="1.0"?>
<root>
    <para>This is para
        <footnote xtra="winding up of trading">1. The first Companies Ordinance having force in the territories which eventually</footnote>
        <footnote>2. The ..territories which eventually</footnote>
        <footnote xtra="winding up of trading">3. The first Companies having force in the territories which eventually</footnote>
        <footnote xtra="winding up of trading">4. The first Companies having force in the territories which eventually</footnote>
    </para>
</root>

We need to apply the color to differentiate the keywords in the output file.

Please guide..

Thanks

Martin Honnen · October 31st, 2009, 07:12 AM

Do you want to use XSLT 2.0 or 1.0? With 2.0 you can use xsl:analyze-string e.g.

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xsd="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xsd"
  version="2.0">
  
  <xsl:param name="term" as="xsd:string" select="'Ordinance'"/>
  <xsl:param name="col" as="xsd:string" select="'red'"/>
  
  <xsl:output method="html" indent="yes"/>
  
  <xsl:template match="footnote">
    <div>
      <xsl:variable name="pattern"
                    as="xsd:string"
                    select="concat('(^|\s+|[,.!?])(', $term, ')(\s+|[,.!?]|$)')"/>
      <xsl:analyze-string select="." regex="{$pattern}">
        <xsl:matching-substring>
          <xsl:value-of select="regex-group(1)"/>
          <span style="color: red;">
            <xsl:value-of select="regex-group(2)"/>
          </span>
          <xsl:value-of select="regex-group(3)"/>
        </xsl:matching-substring>
        <xsl:non-matching-substring>
          <xsl:value-of select="."/>
        </xsl:non-matching-substring>
      </xsl:analyze-string>
    </div>
  </xsl:template>

</xsl:stylesheet>

would output the 'footnote' elements as

Code:

<div>1. The first Companies <span style="color: red;">Ordinance</span> having force in the territories which eventually
</div>

<div>2. The ..territories which eventually</div>

<div>3. The first Companies having force in the territories which eventually</div>

<div>4. The first Companies having force in the territories which eventually</div>

rangeshram · November 3rd, 2009, 05:41 AM

Dear Martin,

When uses the above xslt it shows the below error....

Code:

Description: Could not find function: regex-group

It would be really great if you solve this at earliest.

Thanks in advance..

mhkay · November 3rd, 2009, 05:57 AM

>
Could not find function: regex-group
That means you're trying to run 2.0 code with a 1.0 XSLT processor.

rangeshram · November 3rd, 2009, 06:46 AM

Thanks Mr. Michael, I have changed the processor to Saxon and it works as our expected level ..

Cheers