Retreiving single record in XSLT

nelly78 · November 14th, 2009, 11:42 AM

Hi All,

I have a XML document which contains duplicate data in the elements.

What i want in xslt just to retreive unique date for displaying.

For example: In XML there are two record with the same data i just want to retireive one records from XML in XSLT.

or is there any way to restrict duplicate record using XML Schema.

Below is my XML :

Code:

<?xml version="1.0" encoding="UTF-8"?>
<Users>
    <User>       
               
        <firstname>john</firstname>
        <lastname>walker</lastname>
                   
    </User>
    <User>    
        <firstname>john</firstname>
        <lastname>walker</lastname>
    </User>
</Users>

Below is the XSLT in that i am retrieving data :

Code:

<xsl:template match="user">
        <xsl:call-template name="user">
            <xsl:with-param name="firstname">
                <xsl:apply-templates select="./firstname"/>
            </xsl:with-param>
            <xsl:with-param name="lastname">
                <xsl:apply-templates select="./lastname"/>
            </xsl:with-param>
 </xsl:call-template>
</xsl:template>
 
<xsl:template name="user">
        <xsl:param name="firstname"/>
        <xsl:param name="lastname"/>
 
        <!-- Rest of the code goes here -->         
        
</xsl:template>

How to retrive one record if records are duplicate?

Thanks
Nelly

mhkay · November 14th, 2009, 11:48 AM

Google for "XSLT grouping". In XSLT 2.0 there's an instruction xsl:for-each-group which makes this easy. In XSLT 1.0 there's a coding technique called Muenchian grouping. In either case, you can use concat(firstname, '|', lastname) as the grouping key.

Martin Honnen · November 14th, 2009, 11:52 AM

With XSLT 2.0 you have xsl:for-each-group to group items, then you could process only the first item in each group to avoid duplicates e.g.

Code:

<xsl:template match="Users">
  <xsl:for-each-group select="User" group-by="concat(firstname, '|', lastname)">
    <!-- here . will select the first item in each group so you could for instance output that with e.g -->
    <xsl:copy-of select="."/>
  </xsl:for-each-group>
</xsl:template>

With XSLT 1.0 you can use Muenchian grouping to group items and then again you could process the first item in each group e.g.

Code:

<xsl:key name="k1" match="User" use="concat(firstname, '|', lastname)"/>

<xsl:template match="Users">
  <xsl:for-each select="User[generate-id() = generate-id(key('k1', concat(firstname, '|', lastname))[1])]">
      <xsl:copy-of select="."/>
  </xsl:for-each>
</xsl:template>