labeling duplicates

dexter62 · November 23rd, 2009, 03:08 PM

say I have the following

{ A, B, B, C, D, E, E, F, F, F, G }

now that should be converted into

{ A, B1, B2, C, D, E1, E2, F1, F2, F3, G }

In procedural piece of cake. Should be easy enough in XSLT I guess, but not for me!

In the problem at hand the sets are really elements and the labels A,B.. the values of their name attributes.

mhkay · November 23rd, 2009, 03:27 PM

A standard grouping problem, therefore very easy in XSLT 2.0, rather harder in XSLT 1.0.

In 2.0 it's simply

Code:

<xsl:for-each select="*" group-adjacent=".">
  <xsl:for-each select="current-group()">
     <xsl:value-of select="concat(., position())"/>
  </
</

dexter62 · November 24th, 2009, 11:20 AM

Quote:

Originally Posted by mhkay

A standard grouping problem, therefore very easy in XSLT 2.0, rather harder in XSLT 1.0.

In 2.0 it's simply

Code:

<xsl:for-each select="*" group-adjacent=".">
  <xsl:for-each select="current-group()">
     <xsl:value-of select="concat(., position())"/>
  </
</

Looks great! However, we currently use no XSLT 2 but 1.1 and I am not in the position to change this. Is there any neat way to go about it in 1.1?

Thanks again.

mhkay · November 24th, 2009, 11:34 AM

Search for positional grouping. Sorry, I don't write code in XSLT 1.0 any more for cases where 2.0 is so much easier - if you insist on using old technology, you'll have to take the pain.

dexter62 · November 24th, 2009, 12:10 PM

Quote:

Originally Posted by mhkay

Search for positional grouping. Sorry, I don't write code in XSLT 1.0 any more for cases where 2.0 is so much easier - if you insist on using old technology, you'll have to take the pain.

Yeah, I see what you mean. I'll forward the message...

Martin Honnen · November 24th, 2009, 12:51 PM

If the values (e.g. A, B, C) in the input are sorted and already adjacent then you can simply group by that value with Muenchian grouping as follows:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  
  <xsl:output indent="yes"/>
  
  <xsl:key name="k1" match="foo" use="@name"/>
  
  <xsl:template match="root">
    <xsl:copy>
      <xsl:for-each select="foo[generate-id() = generate-id(key('k1', @name)[1])]">
        <xsl:variable name="current-group" select="key('k1', @name)"/>
        <xsl:choose>
          <xsl:when test="count($current-group)&gt; 1">
            <xsl:for-each select="$current-group">
              <foo name="{@name}{position()}"/>
            </xsl:for-each>
          </xsl:when>
          <xsl:otherwise>
            <xsl:copy-of select="."/>
          </xsl:otherwise>
        </xsl:choose>
       </xsl:for-each>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

That will transform

Code:

<root>
  <foo name="A"/>
  <foo name="B"/>
  <foo name="B"/>
  <foo name="C"/>
  <foo name="D"/>
  <foo name="D"/>
  <foo name="D"/>
  <foo name="E"/>
  <foo name="E"/>
  <foo name="F"/>
</root>

to

Code:

<root>
   <foo name="A"/>
   <foo name="B1"/>
   <foo name="B2"/>
   <foo name="C"/>
   <foo name="D1"/>
   <foo name="D2"/>
   <foo name="D3"/>
   <foo name="E1"/>
   <foo name="E2"/>
   <foo name="F"/>
</root>

dexter62 · November 26th, 2009, 09:21 AM

Hi certainly this looks like it. Sorry I had not had the time to check earlier, I will be trying this later today. Thanks!