XSLT with XPATH

[email protected] · December 21st, 2009, 11:17 AM

Hi,

I have an xml file which contain TABLES. As per the width of table I have to decide whether the table will transform to html or convert as an Image.

I'm going with logic where I'm taking the longest word of column as the length of that particular column. In the last I will add the length of all the columns (longest words). If it is more than 16 characters then the table will not transform.

And if it is less than 16 characters then it will transform.

I have write some code for the same but I'm stuck at XPath where I have to check the longest word in that column and then add all the columns to get the column width.

Below is XML file and XSLT code. Can you please look into this and do the needful. It is bit urgent.

Thanks,
Anil Yadav

XML File

Code:

<?xml version="1.0" encoding="UTF-8"?>
<body>
<TABLE border="0" width="100%" align="center" cellpadding="0" cellspacing="0" style="font-size: 10pt; font-family: 'Times New Roman', Times; color: #000000; background: #FFFFFF">
<TR>
<TD>Cell 1</TD>
<TD>Some text</TD>
<TD>Some text</TD>
<TD>Some text</TD>
</TR>
<TR>
<TD>Cell 2</TD>
<TD>Some text</TD>
<TD>Some more text</TD>
<TD></TD>
</TR>
<TR>
<TD>Cell 3</TD>
<TD>Less</TD>
<TD>Very very less</TD>
<TD>Sample</TD>
</TR>
</TABLE>
<TABLE>
<TR>
<TD>Cell 1</TD>
<TD>So</TD>
<TD>So</TD>
<TD>So</TD>
</TR>
<TR>
<TD>Cell 2</TD>
<TD>So</TD>
<TD>So</TD>
<TD></TD>
</TR>
<TR>
<TD>Cell 3</TD>
<TD></TD>
<TD>Very</TD>
<TD>Sam</TD>
</TR>
</TABLE>
</body>

XSLT CODE

Code:

<xsl:template match="TABLE">
  <xsl:variable name="colCount" select="TR[1]//TD"/>
  <xsl:for-each select="TR">
   <xsl:for-each select="TD">
    <xsl:for-each-group group-by="." select="for $x in tokenize(string(.), ' ') return string-length(($x))">
     <!--xsl:if test="string-length(current-grouping-key())"-->
     <word word="{current-grouping-key()}"/>
     <!--/xsl:if-->
    </xsl:for-each-group>
   </xsl:for-each>
  </xsl:for-each>

 </xsl:template>

mhkay · December 21st, 2009, 11:46 AM

The sum over all columns of the longest word in the column is (with TABLE as the context node)

Code:

<xsl:function name="f:column" as="element(TD)*">
  <xsl:param name="table" as="element(TABLE)"/>
  <xsl:param name="col" as="xs:integer"/>
  <xsl:sequence select="$table/TR/TD[$col]"/>
</xsl:function>

<xsl:function name="f:longest-word-in-column" as="xs:integer">
  <xsl:param name="column" as="element(TD)*"/>
  <xsl:sequence select="max(for $e in $column return 
                                       for $t in tokenize($e, '\s')
                                        return string-length($t))"/>
</xsl:function>

<xsl:variable name="table" select="."/>
<xsl:value-of select="sum(for $i in 1 to count($table/TR[1]/TD)
                                   return f:longest-word-in-column(f:column($table, $i)))"/>

Not tested.

[email protected] · December 22nd, 2009, 02:31 AM

Hi Michael,

Thanks for your reply.

I get the following error message while running the above code:

An empty sequence is not allowed as the result of function f:longest-word-in-column()

XSLT

Code:

 <xsl:template match="TABLE">
  <xsl:variable name="table" select="."/>
  <xsl:value-of select="sum(for $i in 1 to count($table/TR[1]/TD)
   return f:longest-word-in-column(f:column($table, $i)))"/>
 </xsl:template>


<!--Functions-->
 <xsl:function name="f:column" as="element(TD)*">
  <xsl:param name="table" as="element(TABLE)"/>
  <xsl:param name="col" as="xs:integer"/>
  <xsl:sequence select="$table/TR/TD[$col]"/>
 </xsl:function>
 
 <xsl:function name="f:longest-word-in-column" as="xs:integer">
  <xsl:param name="column" as="element(TD)*"/>
  <xsl:sequence select="max(for $e in $column return 
   for $t in tokenize($e, '\s')
   return string-length($t))"/>
 </xsl:function>

mhkay · December 22nd, 2009, 04:13 AM

I warned you it wasn't tested.

[email protected] · December 22nd, 2009, 04:48 AM

Michael,

The code is perfectly working on the tables where the column(s) are not blank. Can you please suggest what should I do for that. If you wish I can send you the table in which I'm facing the problem.

Thanks for all your support and help.

Thanks,
Anil Yadav

mhkay · December 22nd, 2009, 05:01 AM

Try replacing max(EXPR) by max((0, EXPR)). Then if EXPR is empty, max() will return zero. Or you might want to return say 3 so the column always has some width.

[email protected] · December 22nd, 2009, 09:40 AM

Thanks a lot, Michael!!!