can we create the tags dynamically

anarleti · March 11th, 2010, 09:08 AM

Hi,

I have small question to ask ..

can we create the tags dynamically

my sample xml:
================
<sample>
<AA>10</AA>
<AA>20</AA>
<AA>30</AA>
<AA>40</AA>
<AA>30</AA>
<AA>10</AA>
<AA>20</AA>
<AA>20</AA>
<AA>40</AA>
<AA>50</AA>
<AA>60</AA>
<AA>10</AA>
</sample>

i have to writ my xsl so that
the tags names should be like below
for every 4 records the tag name should be same and should increment by 1 for the next record

My out put should be...
=============================

<done>
<1>10</1>
<1>20</1>
<1>30</1>
<1>40</1>
<2>30</2>
<2>10</2>
<2>20</2>
<2>20</2>
<3>40</3>
<3>50</3>
<3>60</3>
<3>10</3>
</done>

Any Suggestions ??

Thanks
Anil

Martin Honnen · March 11th, 2010, 09:14 AM

With XML a digit is not allowed as the first letter in a name so the output you describe is not even XML.
Other than that you can of course create elements dynamically with computed named using xsl: element.
And you can group the input you have in chunks of four elements, how you do that easily depends on the XSLT version you use. Do you use XSLT 2.0 or 1.0?

samjudson · March 11th, 2010, 09:16 AM

You can create tags using the <xsl:element> instruction.

However '1' isn't a valid XML element name, as they cannot start with numbers.

anarleti · March 11th, 2010, 09:24 AM

Thanks for your quick reply,

iam using XSLT 2.0 version

if numbers isn't a valid XML element name
i will be happy atleast instead of "1" if i get like "AA1"

Martin Honnen · March 11th, 2010, 09:32 AM

With XSLT 2.0 you can use for-each-group:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">
  
  <xsl:output indent="yes"/>
  
  <xsl:template match="sample">
    <done>
      <xsl:for-each-group select="AA" group-by="(position() - 1) idiv 4">
        <xsl:for-each select="current-group()">
          <xsl:element name="AA{current-grouping-key() + 1}">
            <xsl:value-of select="."/>
          </xsl:element>
        </xsl:for-each>
      </xsl:for-each-group>
    </done>
  </xsl:template>
 
</xsl:stylesheet>

anarleti · March 13th, 2010, 03:17 AM

Hi,

i have got my required out put with the given logic.

Thanks for your time and timely suggestion :)

Regards
Anil