Display HTML Attributes from XML Attributes

rangeshram · March 27th, 2010, 02:16 AM

Dear All,

We want to use the HTML paragraph attribute based on the xml attribute from the element <rx.p>

XML:
<rx.p justify="full" left-indent="2" first-indent="1"><rx.text>In the event either (a) no such appeal is made by the Purchaser within fourteen (14) working days from the date of receipt by the Purchaser.</rx.text></rx.p>

We're using the below xslt using SAXAN and XSLT2.0 (Oxygen Editor):
XSLT:

Code:

 
<xsl:template match="rx.p">
        <xsl:variable name="Findent"><xsl:value-of select="@first-indent"/></xsl:variable>
        <xsl:variable name="Lindent"><xsl:value-of select="@left-indent"/></xsl:variable> 
 <xsl:choose>
                <xsl:when test="@justify='full'">
                    <p align="justify">
                        <xsl:if test="$Findent = '1'">
                            <xsl:attribute name="style">text-indent:.3in;</xsl:attribute>
                         </xsl:if>
                        <xsl:if test="$Lindent = '1'">
                            <xsl:attribute name="style">margin-left:.3in;</xsl:attribute>
                         </xsl:if>
 
                        <xsl:if test="$Findent = '1.5'">
                            <xsl:attribute name="style">text-indent:.4.5in;</xsl:attribute>
                         </xsl:if>
                        <xsl:if test="$Lindent = '1.5'">
                            <xsl:attribute name="style">margin-left:.4.5in;</xsl:attribute>
                         </xsl:if>
 
                        <xsl:if test="$Findent = '2'">
                            <xsl:attribute name="style">text-indent:.6in;</xsl:attribute>
                         </xsl:if>
                        <xsl:if test="$Lindent = '2'">
                            <xsl:attribute name="style">margin-left:.6in;</xsl:attribute>
                         </xsl:if>
 
                       <xsl:if test="$Findent = '2.5'">
                            <xsl:attribute name="style">text-indent:.7.5in;</xsl:attribute>
                         </xsl:if>                    
                        <xsl:if test="$Lindent = '2.5'">
                            <xsl:attribute name="style">margin-left:.7.5in;</xsl:attribute>
                         </xsl:if>
 
                        <xsl:if test="$Findent = '3'">
                            <xsl:attribute name="style">text-indent:.9in;</xsl:attribute>
                         </xsl:if>                    
                        <xsl:if test="$Lindent = '3'">
                            <xsl:attribute name="style">margin-left:.9in;</xsl:attribute>
                         </xsl:if>
 
                       <xsl:apply-templates/>
                    </p>    
                </xsl:when>
</xsl:choose>

Using above XSLT the output HTML:
<p align="justify" style="margin-left:.6in;">In the event either (a) no such appeal is made by the Purchaser within fourteen (14) working days from the date of receipt by the Purchaser.</p>

The problem in the above HTML is only the attribute "margin-left" is there but not "text-indent". Since we're new to this Transformation please guide us to modify the above code and generates the HTML as below.

Required HTML:
<p align="justify" style="margin-left:.6in; text-indent:.3in">In the event either (a) no such appeal is made by the Purchaser within fourteen (14) working days from the date of receipt by the Purchaser.</p>

Can someone please help...

samjudson · March 27th, 2010, 05:02 AM

The reason you are only seeing one of the style properties is because the second style attribute is overwriting the first one, not adding to it.

If the @first-indent and @left-indent attributes are always there then following would be much simpler:

Code:

<p align="justify" style="margin-left:.{@left-indent*3}in;text-indent:.{@first-indent*3}in;">
    <xsl:apply-templates/>
</p>

If one or the other is likely to not exist then you'd have to use <xsl:attribute> ut put all your processing inside the one attribute:

Code:

<p align="justify">
    <xsl:attribute name="style">
        <xsl:if test="@left-indent">margin-left:.<xsl:value-of select="@left-indent*3"/>in;</xsl:if>
        <xsl:if test="@first-indent">text-indent:.<xsl:value-of select="@first-indent*3"/>in;</xsl:if>
    </xsl:attribute>
    <xsl:apply-templates/>
</p>

rangeshram · March 27th, 2010, 05:13 AM

Thanks Samjudson for your code and explanation. It's works as expected here...

mhkay · March 27th, 2010, 01:14 PM

One other point. Don't do this:

Code:

<xsl:variable name="Findent"><xsl:value-of select="@first-indent"/></xsl:variable>

It's much simpler and more efficient to write:

Code:

<xsl:variable name="Findent" select="@first-indent"/>

In the first case you are constructing a new XML tree; in the second case the variable is simply a reference to an existing node in an existing tree.