template match

heightsofdelites · May 26th, 2010, 07:17 PM

I am somewhat of an xslt newbie and I am sure that it is something very simple. The template match on the root element is not firing. I suspect it has something to do with the default namespace (xmlns="http://www.comp.com/94x/app") for the document as when I remove it the template fires.

The input.xml document:

<?xml version="1.0" encoding="US-ASCII"?>
<WORKORDER xmlns="http://www.comp.com/94x/app" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:ns0="http://www.w3.org/2001/XMLSchema-instance" ns0:schemaLocation="http://www.comp.com/94x/app ../94x/EFTUunisysLocal.xsd">
<WO-DATE/>
<WO-TIME/>
<SYSTEM-ID>ms00164b.comp.com</SYSTEM-ID>
<RUN-ID>unisys_eod</RUN-ID>
<SUBSYSTEM-ID>94x</SUBSYSTEM-ID>
<GFN>unisys_eod0526</GFN>
<CAT-DATE>20100526</CAT-DATE>
<CAT-TIME>162028</CAT-TIME>
</WORKORDER>

The xsl:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns="http://www.comp.com/94x/app">
<xsl:output method="xml" version="1.0" encoding="US-ASCII" indent="yes"/>

<xsl:template match="WORKORDER">
workOrder
<xsl:apply-templates select="@*|node()"/>
<xsl:value-of select="namespace-uri()"></xsl:value-of>
<xsl:value-of select="local-name()"></xsl:value-of>
</xsl:template>

</xsl:stylesheet>

This is the resultant output from the above:
<?xml version="1.0" encoding="US-ASCII"?>

ms00164b.comp.com
unisys_eod
94x
unisys_eod0526
20100526
162028

mrame · May 27th, 2010, 03:46 AM

Try with the below

Code:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://www.comp.com/94x/app">
<xsl:output method="xml" version="1.0" encoding="US-ASCII" indent="yes"/>
<xsl:template match="/">
workOrder
<xsl:apply-templates select="*[name(.) = 'WORKORDER']" mode="test"/>
</xsl:template>
 
<xsl:template match="*" mode="test">
<xsl:apply-templates select="@*|node()"/>
<xsl:value-of select="namespace-uri()"/>
<xsl:value-of select="local-name()"/>
</xsl:template>
</xsl:stylesheet>

mhkay · May 27th, 2010, 03:56 AM

Read all about matching nodes in namespaces here.

I don't think much of mrame's solution, which tries to ignore the fact that there is a namespace. Namespaces are used for a reason, and ignoring them is the wrong approach. Just declare a prefix and use it wherever you refer to elements in this namespace:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:w="http://www.comp.com/94x/app">
<xsl:output method="xml" version="1.0" encoding="US-ASCII" indent="yes"/>

<xsl:template match="w:WORKORDER">
workOrder
<xsl:apply-templates select="@*|node()"/>
<xsl:value-of select="namespace-uri()"></xsl:value-of>
<xsl:value-of select="local-name()"></xsl:value-of>
</xsl:template>

</xsl:stylesheet>

Alternatively, in XSLT 2.0 you can set default-xpath-namespace="http://www.comp.com/94x/app" and then unprefixed names in XPath expressions and match patterns will be taken as referring to this namespace.

mrame · May 27th, 2010, 04:01 AM

Mike you are right, that was a mistake. Actually I tried declaring a prefix, but did a mistake by declaring it with a different namespace and not with http://www.comp.com/94x/app. Thanks again for pointing out.