Dynamic namespaces

Clemensl · June 17th, 2010, 11:16 AM

Hello :)

I am writing a small XSLT script to translate an incoming soap message to a simple xml data file. I am using Saxon9.

The input looks like this:

PHP Code:


			
<?xml version="1.0" encoding="UTF-8"?>
            <SOAP-ENV:Envelope xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/"
                xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
                <SOAP-ENV:Body>
                    <ns:ContactWS_ContactQueryPage_Output
                        xmlns:ns="urn:crmondemand/ws/contact/">
                        <ns:LastPage>true</ns:LastPage>
                        <ListOfContact xmlns="urn:/crmondemand/xml/contact">
                            <Contact>
                                <ContactFirstName>Fred</ContactFirstName>
                                <IntegrationId>AAPA-1VPNO9</IntegrationId>
                                <ContactLastName>Johnson</ContactLastName>
                            </Contact>
                        </ListOfContact>
                    </ns:ContactWS_ContactQueryPage_Output>
                </SOAP-ENV:Body>
            </SOAP-ENV:Envelope>

The prefered output looks like this:

PHP Code:


			
<?xml version="1.0" encoding="UTF-8"?>
            <data xmlns:saxon2="http://saxon.sf.net/" xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/"
                xmlns:n="urn:/crmondemand/xml/contact">
                <object>
                    <property name="ContactFirstName">Fred</property>
                    <property name="replacewithidentifier">AAPA-1VPNO9</property>
                    <property name="ContactLastName">Johnson</property>
                </object>
            </data>

It works pretty well:

PHP Code:


			
<?xml version='1.0' encoding="ISO-8859-1"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0" xmlns:saxon2="http://saxon.sf.net/" >
    <xsl:output method='xml' />
    <xsl:variable name="modulename"><xsl:value-of select="//mappings/map[@name='module_name']" /></xsl:variable>
    <xsl:variable name="lc_modulename"><xsl:value-of select="lower-case($modulename)" /></xsl:variable>
    <xsl:variable name="crmondemand_namespace_xml">urn:/crmondemand/xml/<xsl:value-of select="$lc_modulename" /></xsl:variable>
    <xsl:template match="/">
    <data xmlns:n="urn:/crmondemand/xml/contact">
        <xsl:variable name="ListOf">//n:ListOf<xsl:value-of select="$modulename" />/n:<xsl:value-of select="$modulename" /></xsl:variable>
        <xsl:for-each select="saxon2:evaluate($ListOf)">
<object>
                <xsl:for-each select="*">
                    <xsl:element name="property">
                        <xsl:attribute name="name">
                            <xsl:choose>
                                <xsl:when test="local-name()='IntegrationId'">replacewithidentifier</xsl:when>
                                <xsl:otherwise><xsl:value-of select="local-name()" /></xsl:otherwise>
                            </xsl:choose>           
                        </xsl:attribute>
                        <xsl:value-of select="." />
                    </xsl:element>
                </xsl:for-each>
            </object>
        </xsl:for-each>
        </data>
    </xsl:template>
</xsl:stylesheet>

Now, instead of defining a concrete namespace in the data tag (<data xmlns:n="urn:/crmondemand/xml/contact">) I want to have a dynamic namespace (the content of the $crmondemand_namespace_xml variable).

How do I accomplish this?

Something like

PHP Code:


			
<data>
     <xsl:namespace name="n" select="$crmondemand_namespace_xml" />

does not work.

Thank you very much in advance

samjudson · June 17th, 2010, 11:20 AM

To create elements with dynamic namespaces I believe you would have to use the <xsl:element> instruction:

Code:

<xsl:element name="data" namespace="{$crmondemand_namespace_xml}">
  ...
</xsl:element>

Clemensl · June 17th, 2010, 11:24 AM

Quote:

Originally Posted by samjudson

To create elements with dynamic namespaces I believe you would have to use the <xsl:element> instruction:

Code:

<xsl:element name="data" namespace="{$crmondemand_namespace_xml}">
  ...
</xsl:element>

With this I get the error:

PHP Code:


			
Error at xsl:for-each on line 16 
  XPST0003: Static error in XPath expression supplied to saxon2:evaluate: XPath syntax error
  at char 17 in {//n:ListOfContact/n:Contact}:
    Prefix n has not been declared
; SystemID: ; Line#: 16; Column#: -1
net.sf.saxon.trans.XPathException: Static error in XPath expression supplied to saxon2:evaluate: XPath syntax error at char 17 in {//n:ListOfContact/n:Contact}:
    Prefix n has not been declared

line 16 is refering to the line

PHP Code:


			
<xsl:for-each select="saxon2:evaluate($ListOf)">

samjudson · June 17th, 2010, 11:31 AM

Seems fairly self explanatory to me. The error says you haven't defined the 'n' prefix. So define it. Typical input XML namespaces are declared on the <xsl:stylesheet> element.

Code:

<xsl:stylesheet xmlns:n="urn:/crmondemand/xml/contact" ...

Clemensl · June 17th, 2010, 11:37 AM

Quote:

Originally Posted by samjudson

Seems fairly self explanatory to me. The error says you haven't defined the 'n' prefix. So define it. Typical input XML namespaces are declared on the <xsl:stylesheet> element.

Code:

<xsl:stylesheet xmlns:n="urn:/crmondemand/xml/contact" ...

That works, but I want it to be dynamic. "contact" should be replaced by the content of the "$lc_modulename" variable...

(The module_name variables are correctly filled, I have only pasted a part of the input XML)

Martin Honnen · June 17th, 2010, 11:40 AM

I might be mistaken but I think you need to create a temporary element node with the namespace declarations you want/need to use in your XPath expressions, then you can use saxon:expression with your XPath, passing in the created temporary element node as the second argument, then you can use saxon:eval on that expression:

Code:

<xsl:variable name="t1" as="element()">
  <data>
    <xsl:namespace name="n" select="$yourVariable"/>
  </data>
</xsl:variable>
<xsl:for-each select="saxon2:eval(saxon2:expression($ListOf, $t1))">

Untested!

mhkay · June 17th, 2010, 11:41 AM

Presumably you also want the prefix n as used in the dynamic XPath expression to be bound to whatever namespace URI is held in the variable $crmondemandnamespace... This is a little trickier: saxon:evaluate() always binds namespace prefixes using the static namespaces declared in the stylesheet. One way out is to avoid using a namespace prefix in the dynamic XPath expression: instead of //n:ListOf<xsl:value-of select="$modulename" />, use //*:ListOf<xsl:value-of select="$modulename" /> perhaps with a predicate [namespace-uri(.) = $p1] where $p1 is the dynamic namespace, passed in as a parameter to saxon:evaluate. Another solution is to use saxon:evaluate-node(), which reads the XPath expression from a node in a document, and takes the namespace prefix bindings from the in-scope namespaces of that node; you could try creating a document dynamically with the right prefix bindings, and then using saxon:evaluate-node() to process an XPath expression held in that dynamic document.

Clemensl · June 17th, 2010, 12:01 PM

Quote:

Originally Posted by mhkay

Presumably you also want the prefix n as used in the dynamic XPath expression to be bound to whatever namespace URI is held in the variable $crmondemandnamespace... This is a little trickier: saxon:evaluate() always binds namespace prefixes using the static namespaces declared in the stylesheet.

Ah! I didn't know that :)

Quote:

One way out is to avoid using a namespace prefix in the dynamic XPath expression: instead of //n:ListOf<xsl:value-of select="$modulename" />, use //*:ListOf<xsl:value-of select="$modulename" />

Ah that works as a workaround, thank you :)

I'll look into your other suggestions later, for now this will suffice, thank you all