Grouping nodes by names

bonekrusher · July 14th, 2010, 07:10 AM

Hi, this question is related to:
grouping by nodes questions

After some thought, I rephrased my question and created an example.

Suppose I want to group elements by name and then put them into "groups". For example:

Input:

Code:

<data>
    <tools>Hammer</tools>
    <conditions>Sunny</conditions>
    <conditions>Dry</conditions>
    <tools>Saw</tools>
    <tools>Nail Gun</tools>
    <safety>Safety Glasses</safety>
    <conditions>Clear</conditions>
</data>

Desired output

Code:

<new>
    <group>
        <conditions>Clear</conditions>
        <conditions>Dry</conditions>
        <conditions>Sunny</conditions>
    </group>
    <group>
        <tools>Hammer</tools>
        <tools>Nail Gun</tools>
        <tools>Saw</tools>
    </group>
</new>

*Assume there can be an infinite number of children of <data>

This is a very simple example. In my actual document, I am processing this information into a FO file for PDF output. I am probably over thinking this one. I appreciate the help.

Thanks

samjudson · July 14th, 2010, 07:15 AM

Code:

<new>
<xsl:for-each-group select="/data/*" group-by="name()">
  <group>
    <xsl:for-each select="current-group()">
      <xsl:element name="{name()}"><xsl:value-of select="."/></xsl:element>
    </xsl:for-each>
  </group>
</xsl:for-each-group>
</new>

Martin Honnen · July 14th, 2010, 07:20 AM

Assuming you still want to exclude safety elements, as you indicated earlier, and assuming you want to sort as well:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">
  
  <xsl:output indent="yes"/>
  
  <xsl:template match="data">
    <new>
      <xsl:for-each-group select="*[not(self::safety)]" group-by="node-name(.)">
        <xsl:sort select="local-name-from-QName(current-grouping-key())"/>
        <group>
          <xsl:for-each select="current-group()">
            <xsl:sort select="string()"/>
            <xsl:copy-of select="."/>
          </xsl:for-each>
        </group>
      </xsl:for-each-group>
    </new>
  </xsl:template>

</xsl:stylesheet>

bonekrusher · July 14th, 2010, 09:01 AM

Awesome - you guys are the best. Thanks