split string based on Character count

ptn77 · August 19th, 2010, 11:27 AM

Hello,
Is there a way to split a string based on Character count using xslt 2.0? I believe the tokenize function allows for splitting string based on delimiter, but I need to be able to split string based on character count. I'm hoping there is a way to do this without having to use template and do a loop.

Thanks in advance!

samjudson · August 19th, 2010, 11:28 AM

Do you mean like the substring function?

ptn77 · August 19th, 2010, 11:42 AM

substring would allow for cutting string before or after a specified character or pattern right? I am looking for something more like the tokenize function where you can split the string giving you an array of strings, but instead of splitting based on delimiter I want to split based on character count or string length.

Thanks for taking the time to read my post.

samjudson · August 19th, 2010, 11:57 AM

No, substring returns a string based on a two numbers, the start index and length.

You could always just use analyse-string using a pattern such as ".{n}" where n is the length you require.

The following example would split a string into 7 character length bits, with the remainder in the last element.

Code:

<xsl:analyze-string regex=".{{7}}" select=".">
	<xsl:matching-substring><item><xsl:value-of select="."/></item></xsl:matching-substring>
	<xsl:non-matching-substring><item><xsl:value-of select="."/></item></xsl:non-matching-substring>
</xsl:analyze-string>

Martin Honnen · August 19th, 2010, 12:04 PM

As an alternative to using xsl:analyze-pattern here is an attempt to implement a tokenize function taking a string and substring-cout:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:mf="http://example.com/2010/mf"
  exclude-result-prefixes="xs mf">
  
  <xsl:function name="mf:tokenize" as="xs:string*">
    <xsl:param name="str" as="xs:string"/>
    <xsl:param name="count" as="xs:integer"/>
    <xsl:for-each-group select="string-to-codepoints($str)" group-by="(position() - 1) idiv $count">
      <xsl:sequence select="codepoints-to-string(current-group())"/>
    </xsl:for-each-group>
  </xsl:function>
  
  <xsl:template name="main">
    <xsl:value-of select="mf:tokenize('1234567890', 3)" separator="|"/>
  </xsl:template>

</xsl:stylesheet>

mhkay · August 19th, 2010, 12:11 PM

Furthermore, you could split 10JAN2008 into parts of length 2,3,4 like this:

Code:

<xsl:analyze-string regex="(.{{2}})(.{{3}})(.{{4}})" select=".">
  <xsl:matching-substring>
    <item day="{regex-group(1)" month="{regex-group(2)}" year="{regex-group(3)}">
  </xsl:matching-substring>
</xsl:analyze-string>

ptn77 · August 19th, 2010, 12:17 PM

Thank you everyone for your replies, I will try your suggestions to see which method works best for me.

ptn77 · August 19th, 2010, 12:29 PM

Quote:

Originally Posted by samjudson

No, substring returns a string based on a two numbers, the start index and length.

You could always just use analyse-string using a pattern such as ".{n}" where n is the length you require.

The following example would split a string into 7 character length bits, with the remainder in the last element.

Code:

<xsl:analyze-string regex=".{{7}}" select=".">
	<xsl:matching-substring><item><xsl:value-of select="."/></item></xsl:matching-substring>
	<xsl:non-matching-substring><item><xsl:value-of select="."/></item></xsl:non-matching-substring>
</xsl:analyze-string>

This method works great for what I'm doing. Thanks!!

ptn77 · August 20th, 2010, 04:23 PM

Quote:

Originally Posted by samjudson

No, substring returns a string based on a two numbers, the start index and length.

You could always just use analyse-string using a pattern such as ".{n}" where n is the length you require.

The following example would split a string into 7 character length bits, with the remainder in the last element.

Code:

<xsl:analyze-string regex=".{{7}}" select=".">
	<xsl:matching-substring><item><xsl:value-of select="."/></item></xsl:matching-substring>
	<xsl:non-matching-substring><item><xsl:value-of select="."/></item></xsl:non-matching-substring>
</xsl:analyze-string>

Is there a maximum number allowed for ".{n}" when using
analyse-string with character count regex?

thanks,

samjudson · August 21st, 2010, 05:18 AM

If there is I shouldn't think it would be one that would affect you - i.e. it would be something like Maximum Integer (2,147,483,647 in 32 bit architecture).

When people ask questions like this however I always worry. Are you saying you have found a value that doesn't work? Are you saying you have written the whole XSLT template but don't have 2 minutes to try it out yourself? Or are you just being curious for the sake of it?