How to copy all elements within the path to the root

CHRD · #1 (**permalink**) September 23rd, 2010, 10:11 AM

Hello,

I am looking for some hours for a solution for a very simple problem:
Copy all leaves from a tree with all elements on the way to the root.

I tried:

java -jar saxon9he.jar -s:in.xml -xsl:test.xsl -o:out.xml

in.xml

Code:

<nodes>
	<node id="a1">
		<node id="b1">
			<node id="c1"/>
			<node id="c2"/>
		</node>
	</node>
	<node id="a2"/>
</nodes>

test.xsl

Code:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<!-- copy elements without children including all the elements within the path to the root (i.e. full path)  -->
<xsl:template match="/">
	<nodes>
		<xsl:apply-templates />
	</nodes>
</xsl:template>

<xsl:template match="node[not(descendant::node)]"> 
	<xsl:for-each select="ancestor-or-self::*[count(ancestor::*)>0]"> 
		<node id="{@id}" />
	</xsl:for-each> 
</xsl:template> 
 
</xsl:stylesheet>

out.xml should be a simple copy of the "full path" to the elements, that do not have any children

Code:

<nodes>
	<node id="a1">
		<node id="b1">
			<node id="c1"/>
		</node>
	</node>
	<node id="a1">
		<node id="b1">
			<node id="c2"/>
		</node>
	</node>
	<node id="a2"/>
</nodes>

with the given stylesheet the xml transforms to a list (not surprisingly).

Code:

<nodes>
<node id="a1"/><node id="b1"/><node id="c1"/>
<node id="a1"/><node id="b1"/><node id="c2"/>
<node id="a2"/>
</nodes>

Any hints how to copy all ancestors of a given node?

Best regards

Chrsitian

Martin Honnen · #2 (**permalink**) September 23rd, 2010, 10:30 AM

Interesting problem, here is an XSLT 2.0 stylesheet that does the job with Saxon 9, at least for the sampleinput you posted:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">
  
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>
  
  <xsl:template match="/*">
    <xsl:copy>
      <xsl:apply-templates select="descendant::*[not(node())]"/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:template match="*[not(descendant::node())]">
    <xsl:variable name="ancestors" select="ancestor-or-self::*[position() lt last()]"/>
    <xsl:apply-templates select="$ancestors[1]" mode="tree">
      <xsl:with-param name="ancestors" select="$ancestors"/>
    </xsl:apply-templates>
  </xsl:template>
  
  <xsl:template match="*" mode="tree">
    <xsl:param name="ancestors"/>
    <xsl:if test="$ancestors intersect .">
      <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:apply-templates mode="tree">
          <xsl:with-param name="ancestors" select="$ancestors"/>
        </xsl:apply-templates>
      </xsl:copy>
    </xsl:if>
  </xsl:template>

</xsl:stylesheet>

CHRD · #3 (**permalink**) September 23rd, 2010, 10:41 AM

Thank you very much. The code is running fine.

The problem looked quite simple to me - the solution quite complicated. Normaly XSLT is exactly the other way. Is this a problem I should better solve within the relational database?

Best regards

Christian

Martin Honnen · #4 (**permalink**) September 23rd, 2010, 11:41 AM

Three templates is a complicated solution? The first template creates the root element of the result tree and select the nodes you are interested in (i.e. those without child nodes) for further processing, then for each of the selected nodes the second template finds the elements forming a subtree you want to copy and the third template does the copying.

As for solving the problem "within the relational database", I don't know how the XML input relates to any relational data so I can't tell anything about that.

Need to download code?

Navigation