Grouping with Multiple Dates

gaza165 · September 27th, 2010, 11:11 AM

Code:

<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<?xml-stylesheet type="text/xsl" href="widgets.xsl"?>

<events>
    <event>
        <title>Garrys Event</title>
        <date>2010-09-10</date>
        <date>2010-12-10</date>
    </event>
    
    <event>
        <title>Nicks Event</title>
        <date>2010-09-10</date>
        <date>2010-12-10</date>
    </event>

</events>

I want to group these events by each of the dates they have specified with the event.

So using the example above it would output

10th October 2010
Garrys Event
Nicks Event

10th December 2010
Garrys Event
Nicks Event

Thanks, sorry if I have not been specific enough.

Thanks

Garry

Martin Honnen · September 27th, 2010, 11:38 AM

Here is an XSLT 2.0 stylesheet:

Code:

<xsl:stylesheet
  version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema">
  
  <xsl:output method="text"/>
  
  <xsl:template match="events">
    <xsl:for-each-group select="event" group-by="date/xs:date(.)">
      <xsl:sort select="current-grouping-key()"/>
      <xsl:value-of select="format-date(current-grouping-key(), '[D1o] [MNn] [Y]')"/>
      <xsl:text>
</xsl:text>
      <xsl:value-of select="current-group()/title" separator="
"/>
      <xsl:text>
</xsl:text>
    </xsl:for-each-group>
  </xsl:template>

</xsl:stylesheet>

You can use Saxon 9 or AltovaXML tools or XQSharp to run XSLT 2.0 stylesheets.

gaza165 · September 27th, 2010, 01:09 PM

Hi Martin,

Thankyou for your feedback.

Garrys Event
2010-09-10
2010-12-10

Nicks Event
2010-09-10
2010-12-10

This is the output im getting....is there some changes that can be made to make it output the following:

10th October 2010
Garrys Event
Nicks Event

10th December 2010
Garrys Event
Nicks Event

so that the events are grouped by the multiple dates instead of the event title?

Thanks

Martin Honnen · September 27th, 2010, 01:20 PM

Which XSLT 2.0 processor did you use? Did you use the code I posted? When I use AltovaXML Tools I get

Code:

10th December 2010
Garrys Event
Nicks Event
10th September 2010
Garrys Event
Nicks Event

gaza165 · September 27th, 2010, 01:20 PM

Sorry I am using just an ordinary web browser... I need it to work in a browser.

mhkay · September 27th, 2010, 01:32 PM

All of today's browsers support only XSLT 1.0. Grouping is much trickier in XSLT 1.0. You'll need to read up about Muenchian grouping - it's well covered in all textbooks.

gaza165 · September 27th, 2010, 01:37 PM

I have tried to do a grouping from tutorials but i cant get it the way i want it...is there any advice you can offer me on how to do it?

mhkay · September 27th, 2010, 01:53 PM

>I have tried to do a grouping from tutorials but i cant get it the way i want it...is there any advice you can offer me on how to do it?

Only by writing a new tutorial, which would probably be no better than the ones you are failing to understand. Best to show us what you have tried, then we can see where you went wrong.

gaza165 · September 27th, 2010, 01:59 PM

Code:

<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<?xml-stylesheet type="text/xsl" href="widgets.xsl"?>

<events>
	<event>
		<date>13th October 2010</date>
		<title>Drum and Bass Night</title>
	</event>
	<event>
		<date>13th October 2010</date>
		<title>Another Event</title>
	</event>
	<event>
		<date>12th December 2010</date>
		<title>Chirstmas Event</title>
	</event>
</events>

and the xsl

Code:

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:key name="events-by-date" match="event" use="date" />
<xsl:template match="events">

<html>
<body>

	<xsl:for-each select="event[count(. | key('events-by-date', date)[1]) = 1]">
		<xsl:sort select="date" />
		<h2><xsl:value-of select="date" /></h2>
		<xsl:for-each select="key('events-by-date', date)">
			<p><xsl:value-of select="title" /></p>
		</xsl:for-each>
	</xsl:for-each>

</body>
</html>

</xsl:template>
</xsl:stylesheet>

This is very nearly there, but as soon as I add another <date> into an <event> it doesnt work.

mhkay · September 27th, 2010, 03:40 PM

You want to group the dates, not the events. Something like this (untested)

Code:

          <xsl:for-each select="date[count(. | key('dates', .)[1]) = 1]">
		<xsl:sort select="." />
		<h2><xsl:value-of select="." /></h2>
		<xsl:for-each select="key('dates', .)">
			<p><xsl:value-of select="../title" /></p>
		</xsl:for-each>
	</xsl:for-each>

where the key has name="dates" match="date" use=".".