creating nested nodes

ehsansad · October 13th, 2010, 09:58 AM

I am trying to create such a structure

Code:

 <be:part id="AAAAB">
      <be:foretak>
         <be:generelleopplysinger>
                <be:navn>Ehsan Sadeghi</be:navn>
                 <be:adresse>
                   <be:postboks>111</be:postboks>
                </be:adresse>
         </be:generelleopplysinger>      
      </be:foretak>
       <be:organisasjon />
    </be:part>

from

Code:

   <be:part id="AAAAB">
      <be:foretak>
        <be:navn>ehsansad</be:navn>
         <be:adresse>
              <be:postboks>111</be:postboks>
         </be:adresse>
      </be:foretak>
        <be:organisasjon />
    </be:part>

I have tried read the part and then apply templates for foretak , navn...., but this does not work so I had to create this ugly code

Code:

 <xsl:template match="be:part">
    <xsl:comment>part</xsl:comment>
    <xsl:text>&#xa;</xsl:text>
    <xsl:element name="be:part">
      <xsl:attribute name="id">
        <xsl:value-of select="@id"/>        
      </xsl:attribute>
      <xsl:apply-templates/>
    </xsl:element>        
  </xsl:template>

  <xsl:template match="be:part/be:foretak">
    <xsl:element name="be:foretak">
      <xsl:element name="be:generelleopplysinger">
        <xsl:element name="be:navn">
          <xsl:apply-templates select="be:navn"/>
        </xsl:element>
      </xsl:element>
      <xsl:apply-templates/>
    </xsl:element>
  </xsl:template>
  
  <xsl:template name="be:navn">    
      <xsl:value-of select="."/>
  </xsl:template>

1- if I use the full path in the <xsl:template name="be:navn"> such
<xsl:template name="be:part/be:foretak/be:navn">
I will get an error for the name which says it is not a correct QName, why don't understand.

2- why can't I just create each node in its own template as such

Code:

 <xsl:template name="be:navn">
    <xsl:element name="be:navn">     
      <xsl:value-of select="."/>
    </xsl:element> 
  </xsl:template>

if I do this the nodes will not be created and I will only get the value of the node.

why can't I get what I'm asking for?

cheers
es

Martin Honnen · October 13th, 2010, 10:05 AM

For all such tasks start with the template

Code:

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

then you only need to add templates for those elements you want to manipulate, in your case you need

Code:

<xsl:template match="be:generelleopplysinger">
  <xsl:apply-templates/>
</xsl:template>

Martin Honnen · October 13th, 2010, 10:10 AM

Sorry, I misread your post, my code would work if you wanted a reverse transformation of what you posted.
In your case you need

Code:

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="be:foretak">
  <xsl:copy>
    <xsl:apply-templates select="@*"/>
    <be:generelleopplysinger>
      <xsl:apply-templates/>
    </be:generelleopplysinger>
  </xsl:copy>
</xsl:template>

ehsansad · October 14th, 2010, 04:57 AM

Thanks Martin for both codes,but this is not working for me. when I create a

Code:

<xsl:template name="be:navn">
    <xsl:element name="be:navn">     
      <xsl:value-of select="."/>
    </xsl:element> 
  </xsl:template>

I still don't get the <be:navn> element. This is really strange since the my other templates are working correctly excpt the template for the <be:part> element

Martin Honnen · October 14th, 2010, 06:09 AM

To give you a complete example, with the input

Code:

<be:part id="AAAAB" xmlns:be="http://example.com/">
    <be:foretak>
      <be:navn>ehsansad</be:navn>
       <be:adresse>
            <be:postboks>111</be:postboks>
       </be:adresse>
    </be:foretak>
    <be:organisasjon />
</be:part>

and the stylesheet

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0"
  xmlns:be="http://example.com/">
  
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="be:foretak">
  <xsl:copy>
    <xsl:apply-templates select="@*"/>
    <be:generelleopplysinger>
      <xsl:apply-templates/>
    </be:generelleopplysinger>
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>

Saxon 6.5.5 outputs

Code:

<be:part xmlns:be="http://example.com/" id="AAAAB">
   <be:foretak>
      <be:generelleopplysinger>
         <be:navn>ehsansad</be:navn>
         <be:adresse>
            <be:postboks>111</be:postboks>
         </be:adresse>
      </be:generelleopplysinger>
   </be:foretak>
   <be:organisasjon/>
</be:part>

So the be:generelleopplysinger has been added. Is that not what you want?

ehsansad · October 14th, 2010, 06:20 AM

well based on the example I gave Yes this does the job. The thing is that the example is a small section of the actual XML file. But I did get an idea to solve the problem. But I was wondering if you could help me understand something. In the original question I have a template by the name of be:navn

Code:

<xsl:template name="be:navn">
    <xsl:element name="be:navn">     
      <xsl:value-of select="."/>
    </xsl:element> 
  </xsl:template>

if I change the name to

Code:

<xsl:template name="be:part/be:foretak/be:navn">

I will get this error from VS 2010:
Error 284 The '/' character, hexadecimal value 0x2F, cannot be included in a name.

Do you know why I'm getting this?

ehsan

Martin Honnen · October 14th, 2010, 06:32 AM

An xsl: template element allows the attributes "name" and "match". "name" needs to be a qualified name, "match" a pattern. So you can use

Code:

<xsl;template match="be:part/be:foretak/be:navn">

as "be:part/be:foretak/be:navn" is a pattern. It is not a qualified name however so you cannot use name="be:part/be:foretak/be:navn"

ehsansad · October 14th, 2010, 06:56 AM

I trully think this is a common mistake between xslt novice programmers:-) thanks