XPathing mixed data

mphare · January 27th, 2011, 03:43 PM

I am using Saxon 9, I also use Oxygen 12.1 on a Windows XP machine.

I have some mixed content such as this:

Code:

<AAA>Some Text
   <BBB>
      <CCC>1</CCC>
      <CCC>2</CCC>
   </BBB>
More Text
   <BBB>
      <CCC>3</CCC>
      <CCC>4</CCC>
      <CCC>5</CCC>
    </BBB>
End of Text
</AAA>

At the end of the day, I'm going to turn this into 6 text strings to be sent to other parts of my XSLT scripts.
The lines will look like:

Some Text1More Text3End of Text
Some Text1More Text4End of Text
Some Text1More Text5End of Text
Some Text2More Text3End of Text
Some Text3More Text4End of Text
Some Text3More Text5End of Text

There will be 0 or more BBB element structures and There may or may not be text before, in between or after the BBB nodes.

My thought is to write a recursive template that would take the AAA structure and if there are no BBB structures, just dump the text node.
If there are BBB structures, get the CCC values for one of the BBB structures, say the left most one, and concat the surrounding text with the selected CCC value and any remaining BBB structures and resend to the template. Then when we bounce back to the first recursion, bump the CCC value to the next value, concat with the text and send it through again. Eventually I will have processed all CCC values for all BBB elements and dumped each text string to a temporary result so I can do something with it later.

My problem, except for maybe doing this the most difficult way possible, is that I don't know how to tell what order the text nodes are with the BBB nodes. So, how can I tell that 'Some Text' preceeds a BBB structure and that 'End of Text' succeeds a BBB structure? I can put just the text nodes in order using text()[1], text()[2], or text()[3] and I can put the BBB nodes in order using ./BBB[1] and ./BBB[2], but how do I get the text() and BBB nodes in the right order with each other?

Also, if you know a better way to do this, I'm all ears (or all eyes in this case)

Thanks,

- m

mphare · January 27th, 2011, 05:17 PM

It appears child::node(), self::text() and self::BBB have potential.

samjudson · January 28th, 2011, 05:25 AM

Well that's certainly not an easy problem to solve.

I've managed to get the following working. It doesn't check for 0 BBB elements - but you could put some simple logic in the AAA template to handle that.

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  
<xsl:output method="text"/>

<xsl:template match="AAA">
	<xsl:apply-templates select="BBB[1]"/>
</xsl:template>

<xsl:template match="BBB">
	<xsl:param name="string"/>
	<xsl:variable name="b" select="."/>
	
	<xsl:for-each select="CCC">
		<xsl:variable name="tmp">
		<xsl:value-of select="normalize-space($b/preceding-sibling::text()[1])"/>
		<xsl:value-of select="normalize-space(.)"/>
		</xsl:variable>
		<xsl:choose>
			<xsl:when test="$b/following-sibling::BBB[1]">
				<xsl:apply-templates select="$b/following-sibling::BBB[1]">
					<xsl:with-param name="string" select="concat($string,string($tmp))"/>
					</xsl:apply-templates>
				</xsl:when>
				<xsl:otherwise>
					<xsl:value-of select="concat($string,$tmp)"/>
					<xsl:value-of select="normalize-space($b/following-sibling::text()[1])"/>
<xsl:text>
</xsl:text>
					</xsl:otherwise>
			</xsl:choose>
	</xsl:for-each>
</xsl:template>

</xsl:stylesheet>

mphare · January 28th, 2011, 11:33 AM

Thanks, Sam. I'll look over your code in more detail.

Here's what I have:

Code:

<!--
   =======================================================================
-->
    <xsl:template name="ParseIterator">
        <xsl:param name="myData"></xsl:param>
        
        
        <xsl:if test="empty($myData//BBB)">
            <xsl:text>&#x0a;</xsl:text>
            <xsl:text>No BBB: </xsl:text>
            <xsl:value-of select="$myData"></xsl:value-of>
        </xsl:if>  
        
        <xsl:if test="exists($myData//BBB)">
            <xsl:text>&#x0a;</xsl:text>
            <xsl:text>Yes BBB: </xsl:text>
            
            <xsl:for-each select="$myData//BBB[1]/CCC">
                <xsl:variable name="temp">
                    <xsl:value-of select=" ancestor::BBB/preceding-sibling::node()"></xsl:value-of>
                    <xsl:value-of select="."></xsl:value-of>
                    <!--
                    <xsl:value-of select="ancestor::BBB/following-sibling::node()"></xsl:value-of>
                    -->
                    <xsl:apply-templates select="ancestor::BBB/following-sibling::node()"></xsl:apply-templates>
                </xsl:variable>
                
                <xsl:call-template name="ParseIterator">
                    <xsl:with-param name="myData" select="$temp"></xsl:with-param>
                </xsl:call-template>
                <!--
                <xsl:text>Dump Temp: </xsl:text>
                <xsl:value-of select="$temp"></xsl:value-of>
                <xsl:text>&#x0a;</xsl:text>
                -->
            </xsl:for-each>
            
        </xsl:if>
        
    </xsl:template>
    
    
    <xsl:template match="*">
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

It's got a lot of the debugging output still included, but it's working.

With this as an input:

Code:

<!--
        =======================================================================
    -->
    <xsl:template match="//ROOT">
        <xsl:text>&#x0a;</xsl:text>
        <xsl:text>Starting...</xsl:text>
        <xsl:text>&#x0a;</xsl:text>
        
        <xsl:variable name="test1">
            <AAA>This is a test string for number 1</AAA>
        </xsl:variable>
        
        <xsl:variable name="test2">
            <AAA>First Text<BBB><CCC>1</CCC><CCC>2</CCC></BBB>Middle Text<BBB><CCC>3</CCC><CCC>4</CCC><CCC>5</CCC></BBB>End Text</AAA>
        </xsl:variable>
        
        <xsl:text>&#x0a;</xsl:text>
        <xsl:text>Test 1: </xsl:text>
        <xsl:call-template name="ParseIterator">
            <xsl:with-param name="myData" select="$test1"></xsl:with-param>
        </xsl:call-template>

        <xsl:text>&#x0a;</xsl:text>
        <xsl:text>Test 2: </xsl:text>
        <xsl:call-template name="ParseIterator">
            <xsl:with-param name="myData" select="$test2"></xsl:with-param>
        </xsl:call-template>
        
        <xsl:text>&#x0a;</xsl:text>

        <xsl:text>...Ending</xsl:text>
        <xsl:text>&#x0a;</xsl:text>
    </xsl:template>

I get this as an output:

Code:

Starting...

Test 1: 
No BBB: This is a test string for number 1
Test 2: 
Yes BBB: 
Yes BBB: 
No BBB: First Text1Middle Text3End Text
No BBB: First Text1Middle Text4End Text
No BBB: First Text1Middle Text5End Text
Yes BBB: 
No BBB: First Text2Middle Text3End Text
No BBB: First Text2Middle Text4End Text
No BBB: First Text2Middle Text5End Text
...Ending