Select nodes whose attribute matches another node's attribute?

nikolai · February 3rd, 2011, 04:46 PM

Hi all,

I'm stumped. I've read through tutorials, examples, forums, and I can't find an answer to my problem. I'm trying to figure out how select a subset of nodes to transform by limiting the selection by attribute value, where the attribute value is not hard-coded -- but is actually determined by another element's attribute value in the same file. (Think foreign keys in relational databases...)

For example, think of a school containing a roster of students, and identifying which students belong in which classrooms. Some students may belong to multiple classrooms.

Code:

<school>
  <classrooms>
    <classroom id="1"><student id="1"><student id="42"> ... </classroom>
    <classroom id="2"><student id="4"><student id="42"> ... </classroom>
  </classrooms>

  <students>
    <student id="1"><name>John Doe</name></student>
    <student id="2"><name>Jane Smith</name></student>
         ...
    <student id="42"><name>Joe Somebody</name></student>
  </students>
</school>

Now, I want to print out all the students, but organized by classroom. I was thinking I'd need to iterate over each classroom, and then print out each student who's ID matched the student listed as being in that room:

Code:

<xsl:template match="/">
   <xsl:for-each select="classrooms/classroom">
     Classroom <xsl:value-of select="@id" />
     <xsl:for-each select="student"><!-- classroom/student, that is -->
           <xsl:apply-templates match="/school/students/student[@id=@id]" /><!-- student info from the roster -->
      </xsl:for-each><!-- student in the classroom -->
   </xsl:for-each><!-- classroom in the school -->
<xsl:template>

In the bold apply-templates statement, I'm trying to say "For each student in the classroom, print the information from the roster for that student." In other words, the first @id is "the ID of the student in the classroom" and the second @id is "the ID of the student in the school roster".

Does this make sense? Is this even possible?

Thanks so much in advance for all your help.
Nik

samjudson · February 3rd, 2011, 06:15 PM

The thing you are missing is the current() function. Inside the predicate (the square brackets) the context becomes the element you are in, so [@id=@id] will always equal true, as the id attribute of every students/student element will always match itself.

current() gives you the context node outside of the current XPath, i.e. the student element inside the classroom. Try [@id=current()/@id] instead.

mhkay · February 4th, 2011, 06:14 AM

Also, when you're doing a join, think of xsl:key. Use xsl:key to define a primary key, and use the key() function to locate its corresponding element using the foreign key as input.

Code:

<xsl:key name="student-key" match="student" use="@id"/>
...
<xsl:for-each select="classroom/student">
   <xsl:apply-templates select="key('student-key', @id)"/>
...

samjudson · February 4th, 2011, 06:18 AM

Should that not be <xsl:key name="student-key" match="students/student" use="@id"/> - as you don't want to include the classroom/student elements in the key.

mhkay · February 4th, 2011, 06:21 AM

Yes, I missed that one. Mind you, I don't think it's a wonderful piece of XML design to use the same element name for two different purposes depending on context.

sflynn1812 · April 18th, 2018, 11:30 AM

I wrote this template which return a variable that tests whether any node attributes or attributes values mismatch. It is a sort of alternative approach to the problem.

Template:

Code:

  <xsl:template name="attribute-value-mismatch">
    <xsl:param name="attributes1" />
    <xsl:param name="attributes2" />
    <attribute-match>
      <xsl:if test="(count($attributes1) != count($attributes2))">
        <attribute />
      </xsl:if>
      <xsl:if test="(count($attributes1) = count($attributes2))">
        <xsl:for-each select="$attributes1">
          <xsl:variable name="attribute1" select="."/>
          <xsl:variable name="result">
            <attroot>
              <xsl:for-each select="$attributes2">
                <xsl:if test="name(.) = name($attribute1/.)">
                  <xsl:if test="not(. = $attribute1/.)">
                    <not-matched-name/>
                  </xsl:if>
                </xsl:if>
                <xsl:if test="name(.) != name($attribute1/.)">
                  <not-matched-name/>
                </xsl:if>
              </xsl:for-each>
            </attroot>
          </xsl:variable>
          <xsl:if test="count(msxsl:node-set($result)//not-matched-name) = count(msxsl:node-set($attributes2))">
            <attribute />
          </xsl:if>
        </xsl:for-each>
      </xsl:if>
    </attribute-match>
  </xsl:template>

Usage:

Code:

<xsl:variable name="attribute-mismatch">
          <xsl:call-template name="attribute-value-mismatch">
            <xsl:with-param name="attributes1" select="$node1/@*"></xsl:with-param>
            <xsl:with-param name="attributes2" select="$node2/@*"></xsl:with-param>
          </xsl:call-template>
        </xsl:variable>
        <xsl:if test="count(msxsl:node-set($attribute-mismatch)//attribute) = 0">...

I have tested it thoroughly and it works without any hard coded attribute names.