Swapping values between Element Name and documentation

chilly · February 8th, 2011, 12:50 PM

Here is an XML
INPUT
------------------
<xsd:element name="SAPIdocRelease" minOccurs="0">
<xsd:annotation>
<xsd:documentation>DOCREL</xsd:documentation>
</xsd:annotation>
<xsd:simpleType>
<xsd:restriction base="xsd:string">
<xsd:maxLength value="4"/>
</xsd:restriction>
</xsd:simpleType>
</xsd:element>

OUTPUT
--------------

<xsd:element name="DOCREL" minOccurs="0">
<xsd:annotation>
<xsd:documentation>SAPIdocRelease</xsd:documentation>
</xsd:annotation>
<xsd:simpleType>
<xsd:restriction base="xsd:string">
<xsd:maxLength value="4"/>
</xsd:restriction>
</xsd:simpleType>
</xsd:element>

"DOCREL" needs to swapped wth "SAPIdocRelease" in generic way.

I have so many fields like that in one file. Doing manually taking longer than expected with cut & paste. Is there a generic way to swap those 2 fields with the exact same structure?

Appreciated in advance

samjudson · February 8th, 2011, 12:53 PM

Generic way?

What have you tried so far?

chilly · February 8th, 2011, 12:56 PM

I need to work on different names in file. So i like to have something with standard xslt conversion with out names of the values mentioned.

I just started working on it with no idea on how to.

Martin Honnen · February 8th, 2011, 01:00 PM

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xsd="http://www.w3.org/2001/XMLSchema"
  version="1.0">

  <xsl:template match="@* | node()">
    <xsl:copy>
       <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="xsd:element/@name">
    <xsl:attribute name="{name()}">
       <xsl:value-of select="../xsd:annotation/xsd:documentation"/>
    </xsl:attribute>
  </xsl:template>

  <xsl:template match="xsd:element/xsd:annotation/xsd:documentation">
    <xsl:copy>
       <xsl:value-of select="../../@name"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

Untested but should give you an idea.

chilly · February 8th, 2011, 01:09 PM

You are genius Martin. Works like a charm. Thanks a bunch