Find and replace in entire doc

imshriram · June 20th, 2011, 04:48 PM

Hello XSLT Gurus,
I need to find for a particular string and replace it with another in the entire document. How to do this?

The catch is, I need this to be done dynamically, i.e i need to run a xpath evaluation before i start transforming.

Input XML:
<Alpha><A><B>Hello</B><C replace="true" toReplace="Hello" replaceValue="Hi" /></Alpha>

Output should be:
<Alpha><A><B>Hi</B><C replace="true" toReplace="Hi" replaceValue="Hi" /></Alpha>

I need to replace all occurrences of "Hello" with "Hi" (according to the Input), irrespective of where it occurs in the document.

Can XSLT do this for me?

mhkay · June 20th, 2011, 06:14 PM

Doing the global replace is easy, provided the strings are not split across multiple text nodes. Just write an identity transformation that uses the identity template for elements:

Code:

<xsl:template match="*" mode="replace">
  <xsl:copy><xsl:apply-templates select="@*|node()" mode="replace"/></xsl:copy>
</xsl:template>

and then does the replacement for attributes and text node:

Code:

<xsl:template match="text()" mode="replace">
  <xsl:param name="from" as="xs:string" tunnel="yes"/>
  <xsl:param name="to" as="xs:string" tunnel="yes"/>
  <xsl:value-of select="replace(., $from, $to)"/>
</xsl:template>
<xsl:template match="@*" mode="replace">
  <xsl:param name="from" as="xs:string" tunnel="yes"/>
  <xsl:param name="to" as="xs:string" tunnel="yes"/>
  <xsl:attribute name="{name()}" select="replace(., $from, $to)"/>
</xsl:template>

Then fire the thing off like this:

Code:

<xsl:apply-templates select="$input" mode="replace">
   <xsl:with-param name="from" as="xs:string" tunnel="yes" select="'Hello'"/>
   <xsl:with-param name="to" as="xs:string" tunnel="yes" select="'Hi'"/>
</xsl:apply-templates>

All that remains is working out how to set the initial parameters - you haven't given enough detail to help with that.

imshriram · June 20th, 2011, 11:29 PM

Hi Kay, Thanks for responding. I was sure Identity transform was my only option, since i had copy all my input XML except for one.

But can you please explain how this code would work?

The first template is used to copy everything, except text and attributes.

When it comes to text() and attributes, you run a replace before actually copying them.

I am not sure on what the last one is for, and also I am not sure how i make it dynamic and not statically typed.

Thanks in advance.