unparsed-entity-uri() w/o path

nwebb · August 31st, 2011, 03:58 AM

I am using unparsed-entity-uri() to resolve graphic entities, but only want the filename without the full path, as the graphics on the target server are in a different path.

I'm able to get the desired result, but have a nagging suspicion that there has to be an easier way to do this, maybe without recursion. Any suggestions?

Source is something like this:

Code:

<?xml version="1.0"?>
<!DOCTYPE cmm [
  <!ENTITY graphic1 SYSTEM "c:\graphics\some_folder\abcd.tif" NDATA ccitt4>
]>
<cmm>
  <sheet gnbr="graphic1"/>
</cmm>

XSL is something like this:

Code:

  <xsl:template match="/">
    <body><xsl:apply-templates/></body>
  </xsl:template>

  <xsl:template match="sheet">
    <xsl:variable name="imgref" select="unparsed-entity-uri(@gnbr)"/>
    <xsl:element name="img">
      <xsl:attribute name="href">
        <xsl:call-template name="getFilename">
          <xsl:with-param name="uri" select="translate($imgref,'\','/')"/>
        </xsl:call-template>
      </xsl:attribute>
    </xsl:element>
  </xsl:template>

  <xsl:template name="getFilename">
    <xsl:param name="uri"/>
    <xsl:choose>
      <xsl:when test="contains($uri,'/')">
        <xsl:call-template name="getFilename">
          <xsl:with-param name="uri" select="substring-after($uri,'/')"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$uri"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

Result is:

Code:

<?xml version="1.0" encoding="UTF-8"?>
<body>
   <img href="abcd.tif"/>
</body>

mhkay · August 31st, 2011, 05:14 AM

The value of unparsed-entity-uri() is supposed to be an absolute URI, which means it should never contain a backslash. That's the theory, at any rate. In practice, of course, products sometimes treat Windows filenames as if they were URIs, so it might be prudent to allow it.

There are much easier ways to do this in XSLT 2.0, but if you're stuck with 1.0, then your code is the right way to do it.