how to prevent xsl to output any particular element

mmmathur06 · September 1st, 2011, 07:01 AM

Hi All,

I have a xml something like this:

Code:

<addres>
    <country>xxxx</country>
    <city>xxxx</city>
    <name>xxxxxxxx</name>
    <street>xxxxxxx</street>
    <!-- like this n number of element can come -->
    </addres>

Out of those all tag any of tag e.g. <name> I don't want to produce in out put xml for exp. output should be like below:

Code:

<addres>
    <country>xxxx</country>
    <city>xxxx</city>
    <street>xxxxxxx</street>
    <!-- like this n number of element can come -->
    </addres>

known way is to apply all templates except <name> element e.g. below

Code:

 <xsl:template match="address">
    <xsl:apply-templates select="country"/>
    <xsl:apply-templates select="city"/>
    <!-- let's not apply template for name-->
    <xsl:apply-templates select="street"/>
    <!-- like this n number of tag can come-->
    </xsl:template>

but the issue is there can n number of tag be come which is difficult to apply-template one by one for all. So my question is there any way to exclude that particular tag to be in output xml?

Thanks in advance
Mohan

samjudson · September 1st, 2011, 07:04 AM

Simply create a template that matches the element you don't want to output that does nothing.

Code:

<xsl:template match="address">
    <xsl:apply-templates/>
</xsl:template>

<xsl:template match="name">
   <!-- Do Nothing -->
</xsl:template>

mmmathur06 · September 1st, 2011, 07:15 AM

Thanks for quick reply samjudson,

Forgot to mention important note that element e.g. <name> required to display under other tag for exp. see in bold face:

Code:

<xsl:template match="address">
    <xsl:apply-templates select="country"/>
    <xsl:apply-templates select="city"/>
    <!-- let's not apply template for name-->
    <xsl:apply-templates select="street"/>
    <!-- like this n number of tag can come-->
    </xsl:template>

<xsl:template match="author">
    <xsl:apply-templates select="author-bio"/>
    <xsl:apply-templates select="name"/>    
    <xsl:apply-templates select="aff"/>   
    </xsl:template>

So i could not simply suppress that tag.

Thanks once again.
Mohan

samjudson · September 1st, 2011, 07:16 AM

So be more specific in your match expression:

Code:

<xsl:template match="address/name">
   <!-- Do Nothing -->
</xsl:template>

mmmathur06 · September 1st, 2011, 07:24 AM

Oops... failed to make you understand once again.
<name> applied in <author> is retrieved from <address> only

Code:

<xsl:template match="author">
    <xsl:apply-templates select="author-bio"/>
    <xsl:apply-templates select="address/name"/>    
    <xsl:apply-templates select="aff"/>   
    </xsl:template>

hope now you will be understand correctly.

Thanks
Mohan

samjudson · September 1st, 2011, 08:46 AM

If you want it to do something in one instance, and something else in another then you could use the "mode" attribute.

Code:

<xsl:template match="address">
  <xsl:apply-templates />
</xsl:template>

<xsl:template match="author">
  <xsl:apply-templates select="author-bio"/>
  <xsl:apply-templates select="address/name" mode="authormode"/>
  <xsl:apply-templates select="aff"/>
</xsl:template>

<xsl:template match="name">
  <!-- normal mode = do nothing -->
</xsl:template>

<xsl:template match="name" mode="authormode">
  <!-- author mode - do something -->
   Name = <xsl:value-of select="."/>
</xsl:template>

mmmathur06 · September 1st, 2011, 12:12 PM

Great, working like charm.

Thanks a lot Sam