Regular expression format in xslt

thaqi498 · November 17th, 2011, 12:37 PM

Hello All,

I need to implement Regular expression functionality for a list of data.

I need the Regex format like this (xxx-xxxxx)

here x= Alphanumeric

The list of data is like this

i/p:
1)aspn-et123
2)1aspnet-12
3)98asp-net.1.0

I need the o/p like this

o/p:
1)asp-net12
2)1as-pnet1
3)98a-spnet

Thanks

Martin Honnen · November 17th, 2011, 01:48 PM

Here is an example with XSLT 2.0, assuming the input is

Code:

<root>
  <item>aspn-et123</item>
  <item>1aspnet-12</item>
  <item>98asp-net.1.0</item>
</root>

then the stylesheet

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">
  
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* , node()"/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:template match="item">
    <xsl:copy>
      <xsl:analyze-string select="replace(., '-', '')" regex="(\w{{3}})(\w{{5}})">
        <xsl:matching-substring>
          <xsl:value-of select="concat(regex-group(1), '-', regex-group(2))"/>
        </xsl:matching-substring>
      </xsl:analyze-string>
    </xsl:copy>
  </xsl:template>
  
</xsl:stylesheet>

outputs

Code:

<root>
  <item>asp-net12</item>
  <item>1as-pnet1</item>
  <item>98a-spnet</item>
</root>