Creating Dynamic attributes to elements

aniljayanti · December 28th, 2011, 12:52 AM

Hi ,

I have been tasked for Creating Dynamic attributes to elements. Below is my code.

getting the below result, but if any new attributes comes then i need to add that attribute into my xslt everytime. So, I want to make it dynamic xslt.

Please help me on this.

Input XML:

<rss version="2.0" xmlns:media="http://search.yahoo.com/mrss/">
<channel>
<item>
<title>this is title</title>
<description>about us</description>
<category/>
<link>www.google.co.in</link>
</item>
<item>
<title>Home</title>
<description>Home page</description>
<category>web<category/>
<link>www.yahoo.com</link>
</item>
</channel>
</rss>

Output xml:

<root version="2.0" xmlns:test="http://search.yahoo.com/mrss/">
<test:item title="this is title" description="about us" link="www.google.co.in" />
<test:item this is title="Home" description="Home page" category="web" link="www.yahoo.com" />
</root>

xslt :

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" encoding="utf-8" omit-xml-declaration="yes" media-type="text/xml; charset=UTF-8" />
<xsl:template match='/'>
<root version="2.0" xmlns:test="http://search.yahoo.com/mrss/">
<xsl:for-each select="rss/channel/item">
<xsl:element name="test:item">

<xsl:if test="title !=''">
<xsl:attribute name ="title">
<xsl:value-of select="title"/>
</xsl:attribute>
</xsl:if>

<xsl:if test="description !=''">
<xsl:attribute name ="description">
<xsl:value-of select="description"/>
</xsl:attribute>
</xsl:if>

<xsl:if test="category !=''">
<xsl:attribute name ="category">
<xsl:value-of select="category"/>
</xsl:attribute>
</xsl:if>

<xsl:if test="link !=''">
<xsl:attribute name ="link">
<xsl:value-of select="link"/>
</xsl:attribute>
</xsl:if>

</xsl:element>
</xsl:for-each>
</root>
</xsl:template>
</xsl:stylesheet>

mhkay · December 28th, 2011, 03:31 AM

Use template rules like this:

Code:

<xsl:template match="item">
<test:item><xsl:apply-templates/></test:item>
</xsl:template>

<xsl:template match="item/*">
<xsl:attribute name="{name()}">
  <xsl:value-of select="."/>
</xsl:attribute>
</xsl:template>

aniljayanti · December 28th, 2011, 05:13 AM

Hi mhkay,

thanks for ur reply,

i tried with below xslt code, but it's not giving correct result. pls help.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:test="http://search.yahoo.com/mrss/">
<xsl:output method="xml" encoding="utf-8" omit-xml-declaration="yes" media-type="text/xml; charset=UTF-8" />

<xsl:template match="item">
<test:item>
<xsl:apply-templates/>
</test:item>
</xsl:template>

<xsl:template match="item/*">
<root version="2.0" xmlns:test="http://search.yahoo.com/mrss/">
<xsl:for-each select="rss/channel/item">
<xsl:element name="test:item">

<xsl:attribute name="{name()}">
<xsl:value-of select="."/>
</xsl:attribute>

</xsl:element>
</xsl:for-each>
</root>
</xsl:template>
</xsl:stylesheet>

giving below result.

<test:item xmlns:test="http://search.yahoo.com/mrss/">
<root version="2.0" />
<root version="2.0" />
.....

thanks.

Martin Honnen · December 28th, 2011, 08:22 AM

You don't need any of your for-each, just use the suggested templates and one template creating the root element if needed and perhaps one suppressing the processing of empty elements:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:test="http://search.yahoo.com/mrss/"
  version="1.0">
  
<xsl:output indent="yes"/>
<xsl:strip-space elements="*"/>
  
<xsl:template match="/rss">
  <rss version="{@version}">
    <xsl:apply-templates/>
  </rss>
</xsl:template>

<xsl:template match="item">
  <test:item>
    <xsl:apply-templates/>
  </test:item>
</xsl:template>

<xsl:template match="item/*[normalize-space()]">
  <xsl:attribute name="{name()}">
    <xsl:value-of select="."/>
  </xsl:attribute>
</xsl:template>

<xsl:template match="item/*[not(normalize-space())]"/>

</xsl:stylesheet>

That stylesheet transforms the input

Code:

<rss version="2.0" xmlns:media="http://search.yahoo.com/mrss/">
<channel>
<item>
<title>this is title</title>
<description>about us</description>
<category/>
<link>www.google.co.in</link>
</item>
<item>
<title>Home</title>
<description>Home page</description>
<category>web</category>
<link>www.yahoo.com</link>
</item>
</channel>
</rss>

into

Code:

<?xml version="1.0" encoding="utf-8"?>
<rss xmlns:test="http://search.yahoo.com/mrss/" version="2.0">
   <test:item title="this is title" description="about us" link="www.google.co.in"/>
   <test:item title="Home" description="Home page" category="web" link="www.yahoo.com"/>
</rss>