String Concate problem

rmani · October 12th, 2012, 06:22 PM

Hi,

I am new to XSLT. Need some assitance in generating a text output using xslt

input XML:

Code:

<data>
<sers>
<ser>sr1</ser>
<ser>sr2</ser>
<ser>sr3</ser>
<ser>sr4</ser>
<ser>sr5</ser>
<ser>sr6</ser>
<ser>sr7</ser>
<ser>sr8</ser>
<ser>sr9</ser>
<ser>sr10</ser>
<ser>sr11</ser>
<ser>sr12</ser>
</sers>
</data>

output needed : (To generate text for every 5 "ser" tag data)

ser: sr1,sr2,sr3,sr4,sr5
ser: sr6,sr7,sr8,sr9,sr10
ser: sr11,sr12

Tried several options to generate this..but not successful. Any help is appreciated!

Martin Honnen · October 13th, 2012, 05:01 AM

Here is an example using XSLT 2.0

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">
  
<xsl:param name="size" select="5"/>
  
<xsl:output method="text"/>

<xsl:template match="/">
  <xsl:for-each-group select="data/sers/ser" group-adjacent="(position() - 1) idiv $size">
    <xsl:text>ser: </xsl:text>
    <xsl:value-of select="current-group()" separator=","/>
    <xsl:text> </xsl:text>
  </xsl:for-each-group>
</xsl:template>

</xsl:stylesheet>

XSLT 2.0 can be used with XSLT 2.0 processors like Saxon 9 or AltovaXML.

rmani · October 13th, 2012, 12:32 PM

Thanks much Martin! That was awesome. Looks like I need to work on my xslt 2.0 knowledge!

We dont use xslt 2.0 version and for-each-group is not working with msxml6.0.dll version.

Is this can be achieved in xslt 1.0 version?

rmani · October 15th, 2012, 12:51 PM

Can this be achieved using XSLT 1.0 version?
Any advice on how to go about it?

Martin Honnen · October 15th, 2012, 01:03 PM

Here is an XSLT 1.0 sample:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  
<xsl:param name="size" select="5"/>
  
<xsl:output method="text"/>

<xsl:template match="/">
  <xsl:for-each select="data/sers/ser[(position() - 1) mod $size = 0]">
    <xsl:if test="position() > 1">
      <xsl:text>
</xsl:text>
    </xsl:if>
    <xsl:text>ser: </xsl:text>
    <xsl:for-each select=". | following-sibling::ser[position() &lt; $size]">
      <xsl:if test="position() > 1">
        <xsl:text>, </xsl:text>
      </xsl:if>
      <xsl:value-of select="."/>
    </xsl:for-each>
    <xsl:text> </xsl:text>
  </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

rmani · October 15th, 2012, 02:24 PM

Thanks Martin. Thats was quick.
This solution worked perfect!