Setting java objectsÂ´ properties

sportinguista · November 14th, 2012, 11:33 AM

Hi,

IÂ´m trying to get current date from epoch time. So I have a xsl variable with number of days since 1970 and I want to get the current date in yyyyMMdd format.

Because I have to process this operation massively, I would like to make it the efficient way.

I was trying to run this code with XSLT/Saxon:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:GregCal="java.util.GregorianCalendar">
...
<xsl:variable name="cal" select="GregCal:getInstance()"/>
<xsl:variable name="temp" select="GregCal:setTimeInMillis($cal, $numberOfDays * 86400000)"/>
...
and get YEAR, MONTH, and DAY from "cal" object.

QUESTION IS: If I use 6.5.5 Saxon it works nice, but if I put the 9.4 EE it ignores the setting method, so "cal" object has always current date (setTimeInMillis is never applied).

Could anyone help me to solve it with 9.4, please?

Thanks a lot. Bye!

mhkay · November 14th, 2012, 12:52 PM

The best place for Saxon-specific questions is the developer community site at http://saxonica.plan.io/

The Saxon optimizer doesn't evaluate a variable if its value is never used. If you need to call an external method for its side-effects, put it in an xsl:value-of where the result of the method appears to be used (even if it's always predictably empty).

However, there's no need for an extension function call here. Doing xs:dateTime('1970-01-01T00:00:00') + xs:duration('PT1D') * $numberOfDays) gives you the answer directly.

sportinguista · November 15th, 2012, 05:51 AM

Thank you very much, Michael. ItÂ´s my first post and itÂ´s certainly an honour for me to be answered by you.

Finally I made this:

Added namespace: xmlns:xs="http://www.w3.org/2001/XMLSchema"
Coded:
<xsl:variable name="period" select="concat('P',$numberDays,'D')"/>
<xsl:variable name="duration" select="xs:duration($period)"/>
<xsl:variable name="finalDate" select="xs:dateTime('1970-01-01T00:00:00') + xs:dayTimeDuration($duration)"/>
<xsl:variable name="formattedDate" select="substring-before($finalDate,'T')"/>
<xsl:value-of select="translate($formattedDate,'-','')"/>

What do you think? Where could I further optimize?

Thank you, Michael :)

Martin Honnen · November 15th, 2012, 06:53 AM

I would use the arithmetic operations defined on the date and dayTimeDuration data types to compute the date, and then I would use the format-date function to format the output:

Code:

<xsl:stylesheet 
  version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">
  
<xsl:output method="text"/>

<xsl:param name="numberOfDays" as="xs:integer" select="365 * 40"/>

<xsl:template match="/">
  <xsl:variable name="finalDate" 
    as="xs:date" 
    select="xs:date('1970-01-01Z') + xs:dayTimeDuration('P1D') * $numberOfDays"/>
  <xsl:value-of select="format-date($finalDate, '[Y0001][M01][D01]')"/>
</xsl:template>

</xsl:stylesheet>

That's basically Mike's suggestion, only using xs:date (as you seem to be interested only in a date but not the time component), plus using format-date to output the yyyyMMdd format you want.

sportinguista · November 15th, 2012, 07:42 AM

Wow! works perfect, Martin.

Thank you too!!

EDIT: Ops! seems this solution is much less efficient than previous :(

Key is "format-date" function. I think IÂ´ll use:

<xsl:value-of select="translate(substring-before($finalDate, 'Z'),'-','')"/>