Extract string by position()

WilliamYou · December 13th, 2012, 06:23 AM

Hello,

Rather than clutter my template with lots of xsl:if statements I thought it would make sense to create a for-each loop. However, running this code

Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" version="2.0">
    <xsl:param name="target" as="xs:anyURI" required="no"/>
    <xsl:param name="types" as="xs:integer" required="no" select="5"/>
    <xsl:variable name="root"><doc/></xsl:variable>

    <xsl:template name="build">
        <xsl:variable name="modes" select="tokenize('CSV XML HTML', ',')" as="xs:string+"/>
        <xsl:for-each select="(1,2,4)">
            <xsl:message select="'Mode : ', $modes[position()]"/>
            <xsl:if test="(floor($types  div .) mod 2 = 1)">
                <!-- <xsl:apply-templates select="$root" mode="xs:QName({$modes[position()]})"/> -->
            </xsl:if>
        </xsl:for-each>
    </xsl:template>
    
    <!-- Generate CSV Output -->
    <xsl:template match="/" mode="CSV">
        <xsl:comment>CSV Builder Template</xsl:comment>
    </xsl:template>
    <!-- Generate XML Output -->
    <xsl:template match="/" mode="XML">
        <xsl:comment>XML Builder Template</xsl:comment>
    </xsl:template>
    <!-- Generate HTML Output -->
    <xsl:template match="/" mode="HTML">
        <xsl:comment>HTML Builder Template</xsl:comment>
    </xsl:template>
    
</xsl:stylesheet>

I get :

Code:

Mode :  CSV XML HTML
Mode :  CSV XML HTML
Mode :  CSV XML HTML

and not

Code:

Mode : CSV
Mode : XML
Mode : HTML

As I had hoped. As a consequence of this my mode=xs:QName({$modes[position()]}) generates an error, hence the comments on it. Can this attribute even be made dynamic?

I have tried lots of variations of this approach but I end up with a similar result. Could someone maybe tell me what / where I am going wrong?

--
William

mhkay · December 13th, 2012, 06:53 PM

An integer predicate E[N] means, by definition, E[position()=N]. So E[position()] means E[position()=position()]; the predicate is therefore always true.

Bind a variable to position() first:

<xsl:variable name="p" select="position()"/>

and then use E[$p]

WilliamYou · December 14th, 2012, 04:44 AM

Thank you once again Mr. Kay. I have re-worked the build template to include your solution

Code:

<xsl:template name="build">
        <xsl:variable name="modes" select="(xs:QName('CSV'), xs:QName('XML'), xs:QName('HTML'))" as="xs:QName+"/>
        <xsl:for-each select="(1, 2, 4)">
            <xsl:variable name="pos" select="position()"/>
            <xsl:variable name="mode" select="$modes[$pos]" as="xs:QName"/>
            <xsl:if test="(floor($types  div .) mod 2 = 1)">
                <xsl:message select="'Selected format : ', $mode"/>
                <xsl:apply-templates select="$root" mode="{$mode}"/>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>

and when applicable I get an xsl:message to the console listing my selection. However, I am still unable to make the mode attribute of the xsl:apply-templates dynamic using this approach. Is it even possible?

I have tried various options here but regardless Oxygen (Saxon-PE 9.4.0.4) tells me that the value used is not a valid QName, so I am beginning to think that this approach simply will not work.

I know it's not the end of the world but it is my preferred solution and I would have liked to have had it working.

Can anyone tell me if making this attribute's value dynamic is possible?

--
William

mhkay · December 14th, 2012, 10:44 AM

No, it's not possible to make the mode dynamic. Sorry I didn't look more closely at your code and only addressed the most immediate problem.

One possibility is to do

Code:

<xsl:variable name="formats" as="element()*>
  <CSV/>
  <HTML/>
  <XML/>
</xsl:variable>

and then

Code:

<xsl:apply-templates select="$formats[$p]">
   <xsl:with-param name="root" select="$root"/>
</xsl:apply-templates>

<xsl:template match="CSV">
  <xsl:param name="root"/>

WilliamYou · December 14th, 2012, 11:21 AM

Thank you again Mr. Kay, very much appreciated.

For those that are interested here is the final template (prior to filling in the blanks of course).

Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" version="2.0">
    <!-- The path and name of the output without an extension -->
    <xsl:param name="target" as="xs:anyURI" required="yes"/>
    <!-- The value of the mask of the template(s) you want to apply -->
    <xsl:param name="types" as="xs:integer" required="yes"/>
    <xsl:variable name="root"><doc/></xsl:variable>
    <xsl:variable name="formats" as="element()*"><CSV/> <HTML/> <XML/> <SQL/></xsl:variable>
    <xsl:template name="build">
        <xsl:for-each select="(1, 2, 4, 8)">
            <xsl:variable name="pos" select="position()"/>
            <xsl:if test="(floor($types  div .) mod 2 = 1)">
                <xsl:apply-templates select="$formats[$pos]">
                    <xsl:with-param name="root" select="$root"/>
                </xsl:apply-templates>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>
    
    <!-- Generate CSV Output -->
    <xsl:template match="CSV">
        <xsl:param name="root"/>
        <xsl:variable name="csvResults" select="concat($target, '.csv')"/>
        <xsl:result-document href="{$csvResults}" method="text" omit-xml-declaration="yes">
            <!-- CSV output code here -->
        </xsl:result-document>
    </xsl:template>
    
    <!-- XML template here. -->
    <!-- SQL template here. -->
    <!-- HTML template here. -->
    <!-- Other templates here ... -->

</xsl:stylesheet>

I hope it's of use to someone.

--
William