xsl:attribute

pietromaria.liuzzo · August 13th, 2013, 12:43 PM

I have a further question:

In my input file I have a series of <lb/> elements

I would like to insert in each of them an attribute @n with a value that is a consecutive number starting from 1.
nevertheless, I would also like to insert 0 as the value when my element node <lb/> is followed by an element node <gap/>

is this possible? is xsl:attribute the right function to use?

Thank you very much

Sincerely

Pietro

mhkay · August 13th, 2013, 01:16 PM

Sounds reasonable. You haven't explained what you want to happen to the consecutive numbers when you insert a zero into the sequence, but I would do it something like

Code:

<xsl:template match="lb">
  <lb>
   <xsl:attribute name="n"><xsl:number/></xsl:attribute>
  </lb>
</xsl:template>

<xsl:template match="lb[following-sibling::*[1][self::gap]]">
  <lb n="0"/>
</xsl:template>

pietromaria.liuzzo · August 14th, 2013, 03:14 AM

Thank you very much!

what I want to happen to the consecutive numbers is that they remain the same, like

Code:

<lb n="0"/><gap/>
<lb n="1"/>
<lb n="2"/>
<lb n="3"/>
<lb n="0"/><gap/>

I also would like to insert consecutive numbers into a div element which is an ancestor of my <lb/>

Code:

<div n="1">
<lb n="0"/><gap/>
<lb n="1"/>
<lb n="2"/>
<lb n="3"/>
<lb n="0"/><gap/>
</div>

<div n="2">
<lb n="0"/><gap/>
<lb n="1"/>
<lb n="2"/>
<lb n="3"/>
<lb n="0"/><gap/>
</div>

I have then added before the code you suggested me the following.

Code:

   <xsl:template match="div">
        
       <div>
            <xsl:attribute name="n"><xsl:number/></xsl:attribute>
        </div>
       
        <xsl:apply-templates/>
    </xsl:template>

what happens now is that my result looks like this

Code:

<div n="1"/>
<lb n="0"/>
<lb n="2"/>
<lb n="3"/>
<lb n="4"/>
<lb n="0"/>

<div n="2"/>
<lb n="0"/>
<lb n="2"/>
<lb n="3"/>
<lb n="4"/>
<lb n="0"/>

there must be still something wrong with my understanding of the basics...

thank you very much indeed for any further help

samjudson · August 14th, 2013, 03:59 AM

Firstly you need to put the xsl:apply-templates inside the output div:

Code:

<div>
   <xsl:attribute .. />
   <xsl:apply-templates/>
</div>

Then you just need to specify a "count" attribute for the xsl:number instruction, basiclaly the "not" of the template given to you above..

Code:

<xsl:template match="lb">
  <lb>
   <xsl:attribute name="n"><xsl:number count="lb[not(following-sibling::*[1][self::gap])]"/></xsl:attribute>
  </lb>
</xsl:template>

pietromaria.liuzzo · August 14th, 2013, 04:01 AM

Thank you very much!

pietromaria.liuzzo · August 14th, 2013, 12:58 PM

what do I have to do if I just want to add those attributes but want to get as a result my initial xml? with this code I am actually getting only my list of well numbered lb and divs.

Please, could you tell me which instruction should I look at?

thank you very much
Pietro

Martin Honnen · August 14th, 2013, 01:09 PM

Use

Code:

<xsl:template match="@* | node()">
  <xsl:copy>
     <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

as the starting point to all such stylesheets, then add the templates to perform the transformations to specific nodes, like the ones already suggested to you in this thread.

pietromaria.liuzzo · September 3rd, 2013, 02:33 PM

Thank you!

I have tried on another file doing this

Code:

 <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>
    
    <xsl:template match="ab">
        <div type="edition">
                    <xsl:choose>
                        <xsl:when test="contains(.,'//')">
                        <xsl:for-each select="tokenize(.,'//')">
                        <div>
                    <xsl:attribute name="n" select="position()"/>
                    <xsl:attribute name="type">textpart</xsl:attribute>
                        <ab><lb/>
                            <xsl:variable name="brackets">
                                <xsl:call-template name="breakbrackets">
                                    <xsl:with-param name="textToBeProcessed" select="."/>
                                </xsl:call-template>
                            </xsl:variable>
                            <xsl:for-each select="$brackets">
                                <xsl:call-template name="upconversion"/>
                            </xsl:for-each>
                        </ab>
                    </div>
                    </xsl:for-each>
                    </xsl:when>
                    <xsl:otherwise>
                        <ab>
                        <lb/>
                            <xsl:variable name="brackets">
                            <xsl:call-template name="breakbrackets">
                                <xsl:with-param name="textToBeProcessed" select="."/>
                            </xsl:call-template>
                        </xsl:variable>
                        <xsl:for-each select="$brackets">
                            <xsl:call-template name="upconversion"/>
                        </xsl:for-each>
                    </ab>
                   </xsl:otherwise>
                    </xsl:choose>
        </div>
    </xsl:template>

but for some reason it returns the file to which I apply this as it is with no changes.

the source file looks like this

Code:

<TEI xmlns="http://www.tei-c.org/ns/1.0" xml:space="preserve" xml:lang="en">
    <teiHeader>
    ...    
    </teiHeader>
    <text>
        <body>
                       
            <div type="bibliography">
    </div>
            
            <div type="edition">
                 <head>Text</head>
                <ab>a lot of text to which I want to apply my templates</ab>
            </div>

            <div type="apparatus"><p> </p></div>

            <div type="translation" xml:lang="Spanish">
                <p>
                    <ref type="URI"/>
                </p>
            </div>
        </body>
    </text>
</TEI>

I do not understand what is that I have done wrong this time... thanks for any advise.