XSLT remove node from XML

Alex123 · September 17th, 2013, 04:20 PM

From the below code, just wants to remove <Endpoint_Collection>
</Endpoint_Collection> nodes using XSLT... your advise really appriciated.

<?xml version="1.0" encoding="utf-8" ?>
<Endpoints>
<Endpoint_Collection>
<Endpoint>
<Settings/>
</Endpoint>
</Endpoint_Collection>
</Endpoints>

Martin Honnen · September 18th, 2013, 05:15 AM

Your description is not precise enough, however any such tasks start with a stylesheet with the template

Code:

<xsl:template match="@* | node()">
  <xsl:copy>
     <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

to which you then add templates for the elements that need special treatment. For instance if you want to remove the "Endpoint_Collection" but keep its children and descendants you use

Code:

<xsl:template match="Endpoint_Collection">
  <xsl:apply-templates/>
</xsl:template>

On the other hand, if you want to delete it completely, including any children and descendants, then use

Code:

<xsl:template match="Endpoint_Collection"/>

Alex123 · September 18th, 2013, 10:14 AM

Thank you. I have tried your following code to remove <Endpoint_Collection>

<xsl:template match="@* | node()">
<xsl:copy>
<xsl:apply-templates select="@* | node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="Endpoint_Collection">
<xsl:apply-templates/>
</xsl:template>

It does not reflect any change on my XML file. Am I missing something?

Thanks

Martin Honnen · September 18th, 2013, 10:22 AM

When I use Saxon 6.5.5 to apply the code

Code:

<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    
<xsl:template match="@* | node()">
  <xsl:copy>
     <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="Endpoint_Collection">
  <xsl:apply-templates/>
</xsl:template>

</xsl:stylesheet>

to the input

Code:

<?xml version="1.0" encoding="utf-8" ?>
<Endpoints>
<Endpoint_Collection>
<Endpoint>
<Settings/>
</Endpoint>
</Endpoint_Collection>
</Endpoints>

I get the output

Code:

<?xml version="1.0" encoding="utf-8"?><Endpoints>

<Endpoint>
<Settings/>
</Endpoint>

</Endpoints>

Are you sure your input is as posted? Or does it have some default namespace declaration like 'xmlns="http://example.com/foo"'?

Alex123 · September 18th, 2013, 11:11 AM

Thanks. I'm using XSLT for my SSRS XML output.
I have executed exact same XSLT that you have provided but the result still showing that node.

Following is my complete code:
<xsl:stylesheet
version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="@* | node()">
<xsl:copy>
<xsl:apply-templates select="@* | node()"/>
</xsl:copy>
</xsl:template>

<xsl:template match="Endpoint_Collection">
<xsl:apply-templates/>
</xsl:template>

<xsl:template match="*">
<xsl:element name="{local-name()}">
<xsl:apply-templates select="@* | node()"/>
</xsl:element>
</xsl:template>
<xsl:template match="/*">
<xsl:apply-templates select="node()" />
</xsl:template>

</xsl:stylesheet>

samjudson · September 18th, 2013, 11:13 AM

I suspect your XML actually isn't as you've shown it, and has a namespace declaration in it.

You need to include this namespace in your XSLT and match the Endpoint_Collection in that namespace.