In the Access report header event, how can I get to the
report recordset? I need to trawl through the report records
before printing them - I may need to edit/delete some of them
before preview/printing. Can I get to the record set in the report
header event code ?

TIA

While there is no "report header event" per se, you can always modify a reports record source at run-time via its RecordSource property. Probably the best place to do that would be in the reports Open event. I've never used a report module to run action queries (Updates/Deletes) before, but its certainly possible. qryTest is a saved query:

Private Sub Report_Open(Cancel As Integer)
    Dim strSQL As String

    DoCmd.SetWarnings (False) 'turns off system messages

    strSQL = "UPDATE qryTest SET TestText = 'OldText' WHERE TestID > 2;"
    DoCmd.RunSQL strSQL

    strSQL = "DELETE * FROM qryTest WHERE TestID = 1"
    DoCmd.RunSQL strSQL

    DoCmd.SetWarnings (True) 'turns on system messages

    ' set reports recordsource
    Reports!rptTest.RecordSource = "qryTest"

End Sub

Might give you some ideas.

Bob

Thanks for the above.

This gets me to the record source but not the recordset.
i want to be able to loop through the records in the record set.

any ideas?

While I'd be inclined to do all this behind a form module, collect dynamic criteria, generate the recordset and then open the report, the ADO is the same. Here is how it might look in your report module:

Private Sub Report_Open(Cancel As Integer)
    Dim cnn As ADODB.Connection
    Dim rst As ADODB.Recordset
    Dim strSQL As String
    Dim strCriteria As String

    Set cnn = CurrentProject.Connection

    strSQL = "SELECT * FROM qryTest"

    Set rst = New ADODB.Recordset
    rst.Open strSQL, cnn, adOpenKeyset, adLockOptimistic

    'DELETE******************************************* *******

    strCriteria = "Test2"

    ' Filter records to be deleted.
    rst.Filter = "TestText = '" & strCriteria & "'"

    ' Delete the records
    If rst.RecordCount > 1 Then
        Do While Not rst.EOF
            rst.Delete
            rst.MoveNext
        Loop
        rst.UpdateBatch
    End If

    rst.Filter = adFilterNone
    rst.Requery

    'UPDATE******************************************* ******

    strCriteria = "Test3"

    ' Updaet records that meet criteria.
    If rst.RecordCount > 1 Then
        Do While Not rst.EOF
            If rst!TestText = strCriteria Then
                With rst
                    !TestText = "Test4"
                    .MoveNext
                End With
            Else
                rst.MoveNext
            End If
        Loop
        rst.UpdateBatch
    End If

     ' Set reports recordsource.
    Reports!rptTest.RecordSource = "qryTest"

    ' clean up
    rst.Close
    Set rst = Nothing
    Exit Sub

ErrorHandler:
    ' clean up
    If Not rst Is Nothing Then
        If rst.State = adStateOpen Then rst.Close
    End If
    Set rst = Nothing

    If Err <> 0 Then
        MsgBox Err.Source & "-->" & Err.Description, , "Error"
    End If

End Sub

HTH,

Bob