Calculating the Tax week (UK)

treadmill · June 16th, 2003, 10:29 AM

Hi All,

Does anyone have any code to calculate what the current tax week is? This refers to the UK tax week.

Many thanks,

Treadmill

David Cameron · June 16th, 2003, 06:51 PM

What defines a UK tax week.

regards
David Cameron

treadmill · June 17th, 2003, 02:08 AM

Hi David,

The tax year begins on 6th April 2003 in the UK. Does this help in working out the tax week?

Regards,

Treadmill

David Cameron · June 17th, 2003, 02:29 AM

Not entirely, but I found a site with some php code to calculate the UK tax week that told me how the date is calculated. The function below will return the date that is the starting day of the tax week for the date you pass in as a parameter. You could get rid of the DayDif variable but the code would be a bit harder to read.

Code:

Function GetTaxWeekStartDay(ByVal curDate)

    Dim YearStart
    Dim DayDif

    If Not IsDate(curDate) Then Exit Function

    ' get the start of the current tax year    
    YearStart = CDate(Year(curDate) & "-04-06")    
    If (YearStart > curDate) Then YearStart = DateAdd("d", -1, YearStart)

    DayDif = DateDiff("d", YearStart, curDate)

    GetTaxWeekStartDay = DateAdd("d", -1 * (DayDif Mod 7), curDate)

End Function

regards
David Cameron

owain · June 17th, 2003, 03:23 AM

Try this function

Code:

Function GetTaxWeek(datDate)

Dim datStartDate
Dim bytTaxWeek

    'Make sure the passed in variable is a date
    If IsDate(datDate) Then
        'Get the 6th April on the year of the passed in date
        datStartDate = DateSerial(Year(datDate), 4, 6)
        'If the passed in date is before the 6th April then go back a year
        If datDate < datStartDate Then datStartDate = DateAdd("yyyy", -1, datStartDate)
        'Get the next Monday
        Do Until UCase(WeekDayName(WeekDay(datStartDate))) = "MONDAY"
            datStartDate = DateAdd("d", 1, datStartDate)
        Loop
        'The tax week is the number of days between the 2 dates divided by 7 plus 1
        bytTaxWeek = Int(DateDiff("d", datStartDate, datDate) / 7) + 1
        'If this is 0 then we are still in the previous tax year
        If bytTaxWeek = 0 Then bytTaxWeek = 52
    End If
    GetTaxWeek = bytTaxWeek

End Function

You pass in the date you want to get the tax week for and it will return the tax week (obvious really :))

I hope this is what you were after.

Regards
Owain Williams

David Cameron · June 17th, 2003, 07:22 PM

I just realised that there was an error in the function I posted. The line:

Code:

If (YearStart > curDate) Then YearStart = DateAdd("d", -1, YearStart)

should read

Code:

If (YearStart > curDate) Then YearStart = DateAdd("yyyy", -1, YearStart)

Actually I think that Owain's function is closer to what you want.

regards
David Cameron